1

我尝试使用 gfortran 编译以下 fortran90 代码，该程序仅输出具有 7 个参数的双精度函数 distance() 的值。当我尝试运行它时，我收到消息“分段错误（核心转储）”但如果我重写

距离（z1，z2，z3，z4，z5，13.0d0，z7）到距离（z1，z2，z3，z4，z5，z6，z7），其中z6的值为13.0d0并重新编译它我得到正确的值13.000。 ..

有谁知道为什么？他们看起来和我一模一样。谢谢

program distancetest
implicit none
double precision::drand,distance
double precision::z1,z2,z3,z4,z5,z6,z7
!*********************************
z1=1.0d0
z2=1.0d0
z3=1.0d0
z4=4.0d0
z5=5.0d0
z6=13.0d0
z7=100.0d0
write(*,*) distance(z1,z2,z3,z4,z5,13.0d0,z7)
end program distancetest
!*********************************
double precision function distance(x1,y1,z1,x2,y2,z2,l)
implicit none
double precision::x1,x2,y1,y2,z1,z2,l,x,y,z
x1=x1-l*dble(floor(x1/l))
y1=y1-l*dble(floor(y1/l))
z1=z1-l*dble(floor(z1/l))
x2=x2-l*dble(floor(x2/l))
y2=y2-l*dble(floor(y2/l))
z2=z2-l*dble(floor(z2/l))
x=min(abs(x1-x2),l-abs(x1-x2))
y=min(abs(y1-y2),l-abs(y1-y2))
z=min(abs(z1-z2),l-abs(z1-z2))
distance=sqrt(x*x+y*y+z*z)
end function distance
4

2 回答 2

2

该函数修改其所有虚拟参数 bar l。将变量以外的任何内容与已修改的虚拟参数相关联是错误的。 13.0d0不是变量，z6是。

于 2013-10-20T00:50:13.773 回答
1

扩展 IanH 的答案，如果您将过程放入模块并使用这些模块，以便编译器可以检查参数的一致性，并且如果您指定参数意图，那么大多数 Fortran 编译器都会为您找到这个问题。

module MyFunc
   implicit none
contains
   double precision function distance(x1,y1,z1,x2,y2,z2,l)
   implicit none
   double precision, intent (inout)::x1,x2,y1,y2,z1,z2
   double precision, intent (in) :: l
   double precision :: x,y,z
   x1=x1-l*dble(floor(x1/l))
   y1=y1-l*dble(floor(y1/l))
   z1=z1-l*dble(floor(z1/l))
   x2=x2-l*dble(floor(x2/l))
   y2=y2-l*dble(floor(y2/l))
   z2=z2-l*dble(floor(z2/l))
   x=min(abs(x1-x2),l-abs(x1-x2))
   y=min(abs(y1-y2),l-abs(y1-y2))
   z=min(abs(z1-z2),l-abs(z1-z2))
   distance=sqrt(x*x+y*y+z*z)
   end function distance
end module MyFunc


program distancetest
use MyFunc
implicit none
double precision::z1,z2,z3,z4,z5,z6,z7
!*********************************
z1=1.0d0
z2=1.0d0
z3=1.0d0
z4=4.0d0
z5=5.0d0
z6=13.0d0
z7=100.0d0
write(*,*) distance(z1,z2,z3,z4,z5,13.0d0,z7)
end program distancetest

例如，来自 gfortran：

write(*,*) distance(z1,z2,z3,z4,z5,13.0d0,z7)
                                   1
Error: Non-variable expression in variable definition context (actual argument to INTENT = OUT/INOUT) at (1)
于 2013-10-20T17:31:14.420 回答