arrays - SAS：使用数组转置表格

Question

我正在尝试重新创建一些与http://support.sas.com/resources/papers/proceedings10/158-2010.pdf上第 9-10 页上的内容相反的代码。因此，与其让一张桌子从宽变长，我希望它从长变宽。

Id Col1  Col2     
1  Val1  A    
1  Val2  B    
2  Val1  C    
2  Val3  D  
3  Val2  E 

转置为：

Id X_Val1 X_Val2 X_Val3  
1  A      B      .
2  C      .      D
3  .      .      E

关于我应该如何处理这件事的任何想法？我知道我应该使用一个数组并尝试创建一个新列 X_Val1 其中 X_Val1 = cat('X',Val1) 其中 X 是一些字符串。

Answer 1

你需要先弄清楚你需要多少个变量。然后，您可以创建变量、使用数组并分配值。

data test;
input id col1 $ col2 $;
datalines;   
1  Val1  A    
1  Val2  B    
2  Val3  C    
2  Val4  D   
2  Val5  E
;
run;

/*Need to get the number of variables that need to be created*/
proc sql noprint;
select max(c)
    into :arr_size
    from
    ( select ID, count(*) as c
        from test
        group by id
    );
quit;

/*Get rid of leading spaces*/
%let arr_size=%left(&arr_size);
%put &arr_size;

data test_t;
set test;
by id;
/*Create the variables*/
format SOME_X1 - SOME_X&arr_size $8.;
/*Create an array*/
array SOME_X[&arr_size];

/*Retain the values*/
retain count SOME_X:;

if first.id then do;
count = 0;
do i=1 to &arr_size;
    SOME_X[i] = "";
end;
end;

count = count + 1;
SOME_X[count] = col2;

if last.id then
    output;

keep id SOME_X:;
run;

Answer 2

我不知道您为什么要使用除PROC TRANSPOSE.

proc transpose data=have out=want prefix='X_';
by id;
id col1;
var col2;
run;