4

我目前正在 Linux 上编写一个 OpenGL 3.1（使用 GLSL 版本 330）应用程序（NVIDIA 360M 卡，使用 313.0 nv 驱动程序），它有大约 15k 行。我的问题是，在我的一个顶点着色器中，我可以通过对实际上应该是无操作的代码进行最小的更改来体验性能急剧下降。

例如：

// With this solution my program runs with 3-5 fps
for(int i = 0; i < 4; ++i) {
  vout.shadowCoord[i] = uShadowCP[i] * w_pos;
}

// But with this it runs with 30+ fps
vout.shadowCoord[0] = uShadowCP[0] * w_pos;
vout.shadowCoord[1] = uShadowCP[1] * w_pos;
vout.shadowCoord[2] = uShadowCP[2] * w_pos;
vout.shadowCoord[3] = uShadowCP[3] * w_pos;

// This works with 30+ fps too
vec4 shadowCoords[4];
for(int i = 0; i < 4; ++i) {
  shadowCoords[i] = uShadowCP[i] * w_pos;
}
for(int i = 0; i < 4; ++i) {
  vout.shadowCoord[i] = shadowCoords[i];
}

或者考虑一下：

uniform int uNumUsedShadowMaps = 4; // edit: I called this "random_uniform" in the original question

// 8 fps
for(int i = 0; i < min(uNumUsedShadowMaps, 4); ++i) {
    vout.shadowCoord[i] = vec4(1.0);
}

// 30+ fps
for(int i = 0; i < 4; ++i) {
  if(i < uNumUsedShadowMaps) {
    vout.shadowCoord[i] = vec4(1.0);
  } else {
    vout.shadowCoord[i] = vec4(0.0);
  }
}

在此处查看整个着色器代码，出现此问题：http: //pastebin.com/LK5CNJPD

就像任何想法都会受到赞赏，关于什么会导致这些。

4

1 回答 1

3

我终于设法找到了问题的根源，并找到了解决方案。

但在正确解决解决方案之前，请让我粘贴最小的着色器代码，用它我可以重现这个“错误”。

顶点着色器：

#version 330 

vec3 CountPosition(); // Irrelevant how it is implemented.

uniform mat4 uProjectionMatrix, uCameraMatrix;

out VertexData {
    vec3 c_pos, w_pos;
    vec4 shadowCoord[4];
} vout;

void main() {
    vout.w_pos = CountPosition();
    vout.c_pos = (uCameraMatrix * vec4(vout.w_pos, 1.0)).xyz;
    vec4 w_pos = vec4(vout.w_pos, 1.0);

    // 20 fps
    for(int i = 0; i < 4; ++i) {
        vout.shadowCoord[i] = uShadowCP[i] * w_pos;
    }

    // 50 fps
    vout.shadowCoord[0] = uShadowCP[0] * w_pos;
    vout.shadowCoord[1] = uShadowCP[1] * w_pos;
    vout.shadowCoord[2] = uShadowCP[2] * w_pos;
    vout.shadowCoord[3] = uShadowCP[3] * w_pos;

    gl_Position = uProjectionMatrix * vec4(vout.c_pos, 1.0);
}

片段着色器：

#version 330

in VertexData {
    vec3 c_pos, w_pos;
    vec4 shadowCoord[4];
} vin;

out vec4 frag_color;

void main() {
    frag_color = vec4(1.0);
}

有趣的是，只需对顶点着色器进行最小的修改，就可以使两种解决方案都以 50 fps 工作。主函数应该修改成这样：

void main() {
    vec4 w_pos = vec4(CountPosition(), 1.0);
    vec4 c_pos = uCameraMatrix * w_pos;

    vout.w_pos = vec3(w_pos);
    vout.c_pos = vec3(c_pos);

    // 50 fps
    for(int i = 0; i < 4; ++i) {
        vout.shadowCoord[i] = uShadowCP[i] * w_pos;
    }

    // 50 fps
    vout.shadowCoord[0] = uShadowCP[0] * w_pos;
    vout.shadowCoord[1] = uShadowCP[1] * w_pos;
    vout.shadowCoord[2] = uShadowCP[2] * w_pos;
    vout.shadowCoord[3] = uShadowCP[3] * w_pos;

    gl_Position = uProjectionMatrix * c_pos;
}

不同之处在于上面的代码从着色器中读取了变量，而底部的代码将这些值保存在临时变量中，并且只写入了变量。

结论：

读取着色器的变化通常被视为一种优化，以减少一个临时变量，或者至少我在互联网上的许多地方都看到过它。尽管有前面的事实，读取一个变量实际上可能是一个无效的 OpenGL 操作，并且可能使 GL 进入一个未定义的状态，在这种状态下，代码中的随机更改可能会触发坏事。

最好的一点是，GLSL 330 规范没有说明从之前写入的 out 变量中读取的内容。可能是因为这不是我应该做的事情。

附言

另请注意，原始代码中的第二个示例可能看起来完全不同，但它在这个小代码片段中的工作方式完全相同，如果读取 out 变量，i < min(uNumUsedShadowMaps, 4)for 循环中的 as 条件会变得非常慢，但是如果 out变化只是写出来的，它不会对性能产生任何改变，而且它也i < min(uNumUsedShadowMaps, 4)适用于 50 fps。

于 2013-10-18T23:59:42.850 回答