2

我试图在 Report_Load 事件中将报告（或表单）的记录集更改为动态调用的 MySQL 存储过程的结果。具体来说，我将如何设置连接？

我查看了将访问表单绑定到存储过程的结果，以及如何将 Microsoft Access 表单绑定到 ADO 记录集。我已经成功地使用直通查询中的硬编码值连接到存储过程，详见Calling Stored Procedures and other SQL statements from MS Access 2003 (Pass Through)。

这是从绑定访问表单到存储过程结果的示例代码- 我想设置连接以使用 MySQL 而不是 SQL Server：

With cn
    .Provider = "Microsoft.Access.OLEDB.10.0"
    .Properties("Data Provider").Value = "SQLOLEDB"
    .Properties("Data Source").Value = "Server"
    .Properties("Integrated Security").Value = "SSPI"
    .Properties("Initial Catalog").Value = "Test"
    .Open
End With

我正在使用 Access 2007。

出于兴趣，这是我用来尝试修改 sp 调用的代码，给出错误“32585 此功能仅在 ADP 中可用”。Gord Thompson 修改实际查询的建议有效，所以我正在使用它。

    If Not CurrentProject.AllForms("foo_frm").IsLoaded Then
        'use hard-coded query (stored procedure) for dev work
        Exit Sub
    End If

    Dim action, startdate, enddate As String
    action = Forms![foo_frm].txtAction

    If action = "cmdDaily" Then
        startdate = Forms![foo_frm].txtYesterday
        enddate = Forms![foo_frm].txtToday
    Else
        startdate = Forms![foo_frm].cboStartDate
        enddate = Forms![foo_frm].cboEndDate
    End If

    Dim cn As New ADODB.Connection
    Dim strConnection As String

    strConnection = "ODBC;DSN=Foo01;UID=root;PWD=Secret;DATABASE=bar"
    With cn
       .Provider = "MSDASQL"
       .Properties("Data Source").Value = strConnection
       .Open
    End With

    Dim prmStartDate, prmEndDate As New ADODB.Parameter
    Dim cmd As New ADODB.Command

    Set prmStartDate = cmd.CreateParameter("startdate", adDate, adParamInput)
    prmStartDate.Value = CDate(startdate)
    cmd.Parameters.Append (prmStartDate)

    Set prmEndDate = cmd.CreateParameter("enddate", adDate, adParamInput)
    prmEndDate.Value = CDate(enddate)
    cmd.Parameters.Append (prmEndDate)

    With cmd
        .ActiveConnection = cn
        .CommandText = "qux_sp"
        .CommandType = adCmdStoredProc
        Set Me.Recordset = .Execute
    End With
4

1 回答 1

1

您已经拥有使用传递查询的报表，因此与其使用代码来摆弄报表的行源，为什么不将报表绑定到传递查询并使用代码来调整其 SQL 语句并调用带有你想要的参数的存储过程？

例如，以下 VBA 代码...

Sub TweakPassThroughQuery()
Dim testID As Long
Dim qdf As DAO.QueryDef, rst As DAO.Recordset
testID = 2  ' this is the parameter we really want to pass to the stored procedure
Set qdf = CurrentDb.QueryDefs("ptq_myproc")
Debug.Print "Existing pass-through query..."
Debug.Print "    " & qdf.SQL
Set rst = qdf.OpenRecordset
Debug.Print "...returns a value like this:"
Debug.Print "    " & rst!col1
rst.Close
Set rst = Nothing
' now tweak the stored procedure call
qdf.SQL = "CALL myproc(" & testID & ")"
Debug.Print "Modified pass-through query..."
Debug.Print "    " & qdf.SQL
Set rst = qdf.OpenRecordset
Debug.Print "...returns a value like this:"
Debug.Print "    " & rst!col1
rst.Close
Set rst = Nothing
Set qdf = Nothing
End Sub

...显示以下输出：

Existing pass-through query...
    CALL myproc(1)
...returns a value like this:
    foo
Modified pass-through query...
    CALL myproc(2)
...returns a value like this:
    bar
于 2013-10-17T09:53:35.470 回答