json - 如何从 Delphi XE3 中的 JSON 对象解析指定值？

Question

我的 JSON 对象如下所示：

{
   "destination_addresses" : [ "Paris, France" ],
   "origin_addresses" : [ "Amsterdam, Nederland" ],
   "rows" : [
      {
         "elements" : [
            {
               "distance" : {
                  "text" : "504 km",
                  "value" : 504203
               },
               "duration" : {
                  "text" : "4 uur 54 min.",
                  "value" : 17638
               },
               "status" : "OK"
            }
         ]
      }
   ],
   "status" : "OK"
}

我需要距离的“504 公里”值。我怎样才能做到这一点？

Answer 1

您可以使用DBXJSON自 Delphi 2010 起包含的单元。

试试这个样本

uses
  DBXJSON;

{$R *.fmx}

Const
StrJson=
'{ '+
'   "destination_addresses" : [ "Paris, France" ], '+
'   "origin_addresses" : [ "Amsterdam, Nederland" ], '+
'   "rows" : [  '+
'      {      '+
'         "elements" : [  '+
'            {  '+
'               "distance" : { '+
'                  "text" : "504 km", '+
'                  "value" : 504203   '+
'               },  '+
'               "duration" : {  '+
'                  "text" : "4 uur 54 min.",  '+
'                  "value" : 17638  '+
'               },  '+
'               "status" : "OK"  '+
'            }   '+
'         ]   '+
'      }  '+
'   ],   '+
'   "status" : "OK"  '+
'}';


procedure TForm6.Button1Click(Sender: TObject);
var
  LJsonObj  : TJSONObject;
  LRows, LElements, LItem : TJSONValue;
begin
    LJsonObj    := TJSONObject.ParseJSONValue(TEncoding.ASCII.GetBytes(StrJson),0) as TJSONObject;
  try
     LRows:=LJsonObj.Get('rows').JsonValue;
     LElements:=TJSONObject(TJSONArray(LRows).Get(0)).Get('elements').JsonValue;
     LItem :=TJSONObject(TJSONArray(LElements).Get(0)).Get('distance').JsonValue;
     ShowMessage(TJSONObject(LItem).Get('text').JsonValue.Value);
  finally
     LJsonObj.Free;
  end;
end;

Answer 2

可以解析 JSON 的库之一是superobject。

要从rows.elements.distance您的 JSON 中获取，代码如下所示：

var
  json         : ISuperObject;
  row_item     : ISuperObject;
  elements_item: ISuperObject;
begin
  json := TSuperObject.ParseFile('C:\json.txt', TRUE); // load whole json here

  for row_item in json['rows'] do // iterate through rows array
    for elements_item in row_item['elements'] do // iterate through elements array
    begin
       WriteLn(elements_item['distance'].S['text']); // get distance sub-json and it's text key as string
    end;
end;

Answer 3

使用 json4delphi 作为导航：

ajt:= TJson.create();
ajt.Parse(StrJson); 
println('dist: '+ajt['rows'].asarray[0].asObject['elements'].asarray[0].asobject['distance'].asobject['text'].asstring);
ait.Free;

要获取元素名称：

 jOb:= ajt.JsonObject;
 for cnt:= 2 to job.count-2 do begin         
   Clabel:= job.items[cnt].name;
   JsArr:= job.values[Clabel].asArray;
   for cnt2:= 0 to jsarr.count-1 do            
     jsobj:= jsarr.items[cnt2].asobject;
     for cnt3:= 0 to jsobj.count do 
       writeln(jsobj['elements'].asarray[0].asobject.items[cnt3].name)
      
 end;