4

[检查下半部分的最后编辑以获取有关主要问题的更新]

我的手机将照片存储在 SD 卡上。我用CameraUI拍照，然后我想分析并删除它。

代码（简化）：

private function startCapture():void
{
    _camera = new CameraUI();
    _camera.addEventListener( MediaEvent.COMPLETE, onCapture );

    _camera.launch(MediaType.IMAGE); //works fine
}


private function onCapture(e:MediaEvent):void
{
    var loader:Loader = new Loader();

    _filePromise = e.data;
    loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onAsyncMediaComplete);
    loader.loadFilePromise(m__filePromise);
}


private function onAsyncMediaComplete(e:Event):void
{
    var loader:Loader = (e.currentTarget as LoaderInfo).loader; 
    //here the loader contains the picture as expected

    //FIXME adds an empty picture instead of deleting
    _filePromise.file.deleteFile();
}

我希望 SD 卡上的图片会被删除，但它仍然存在，并且在它旁边创建了一个新的虚拟文件。我跟踪了文件的 URL 并得到了storage/sdcard0/DCIM/Camera/IMG_20131016_204700.jpg

我的 android 清单包括

<uses-permission android:name="android.permission.WRITE_EXTERNAL_STORAGE" />

编辑：

如本文所示，AIR 创建了两张图片，一张DCIM/Camera在DCIM/100MEDIA. 按照建议，我扫描了 DCIM 的子文件夹中具有相同时间戳（+- 3 秒）和相同大小的图片event.data.file。然后删除这两张图片。这是代码：

var date:Date = m__filePromise.file.modificationDate;
var size:Number = m__filePromise.file.size;
trace("looking for", date.time, size);
var cameraFolder:File = m__filePromise.file.parent.parent;
var pictureFolders:/*File*/Array = cameraFolder.getDirectoryListing();
var pictures:/*File*/Array;
for each(var folder:File in pictureFolders)
{
    pictures = folder.getDirectoryListing();
    for each(var pic:File in pictures)
    {
        if (pic.size == size &&
            Math.abs(pic.modificationDate.time - date.time) < 3000)
        {
            //approximatively the same date, same size, let's delete the copy
            trace("delete", pic.modificationDate.time, pic.size, pic.name);
            pic.deleteFile();
        }
    }
}

问题是它deleteFile不起作用，它会留下一个同名的空文件（0b）。我已经阅读了它的缓存问题，我发现的唯一解决方法是针对本机代码。

4

1 回答 1

2

是的，它通常是 Android 上媒体文件的缓存问题。您必须找到一种方法来启动 Intent.ACTION_MEDIA_MOUNTED 或其他方式来刷新设备的 MediaStore（可能是本机扩展）

另一种解决方案是使用 Camera 类并直接在您的应用中拍照。这是一种极简方式，您可以直接在应用程序中拍照

    private var _video : Video;
    private var _cameraImage : Bitmap;
    private var _camera : Camera;

    /**
     * initilize camera
     */
    private function initCamera() : void {

        //get camera
        _camera = getCamera(CameraPosition.FRONT);
        _camera.setMode(_streamW, _streamH, streamFPS, true);
        _camera.setQuality(0, 100);
        _camPosition = CameraPosition.FRONT;

         //camera preview
        _video = new Video(_streamW, _streamH);
        _video.attachCamera(_camera);


        //rotate        
        var m : Matrix = new Matrix();
        m.rotate(Math.PI / 2);
        m.translate(_video.height, 0);
        this._video.transform.matrix = m;
        addChild(_video);
    }

    /**
     * takes photo and saves to bitmap
     */
    private function onTakePhoto(event : GestureEvent) : void {     
        var cameraBitmap : BitmapData = new BitmapData(_streamH, _streamW, true, 0x0);
        cameraBitmap.draw(_video, _video.transform.matrix);
        _cameraImage = new Bitmap(cameraBitmap);
    }

    /**
     * finds camera in desired position
     */
    private function getCamera(position : String) : Camera {
        for (var i : uint = 0; i < Camera.names.length; ++i) {
            var cam : Camera = Camera.getCamera(String(i));
            if (cam.position == position) return cam;
        }
        return Camera.getCamera();
    }

如果您直接在您的应用程序中拍摄照片，您将失去本机照片应用程序的许多功能，但在操作和保存图像时将具有完全控制权，并且还可以为您的应用程序提供特定的自定义界面。你也可以试试这个原生扩展http://distriqt.com/native-extensions#camera让你直接在应用程序中使用相机的一些更高级的功能。

于 2013-11-11T15:56:34.230 回答