14

该线程讨论了我在 Excel 电子表格中使用 ActiveX 对象时遇到的问题。阅读起来很混乱，最终没有一个连贯的答案。

问题是 100% 可重现的：

  1. 使用扩展坞时在电子表格中打开带有 ActiveX 对象的工作簿
  2. 断开机器与扩展坞的连接，触发分辨率更改（还有其他原因，我的是扩展坞，似乎更改分辨率会导致这种情况）
  3. 单击一个 ActiveX 控件 - 它们会立即调整大小并且字体会改变大小。字体大小的变化不是.Font.Size参数的函数，而是问题发生后无法更改的东西，除了不断增加字体大小

唯一看似权威的解决方案涉及 MS 补丁（不过，几年前它是一个“修补程序”，因此对于完全部署来说似乎并不实用）和注册表编辑，这对我的用例来说不实用。

我正在寻找一种方法：

  1. 防止发生这种变化
  2. 找到最好的解决方法

网上缺乏关于这个问题的权威信息。我打算发布我的工作，但是，它甚至不接近理想，我更喜欢更好的解决方案。

4

8 回答 8

2

我的解决方法是以编程方式遍历工作表上的所有 OLE 对象*并将代码写入调试器，然后在工作表上包含一个基本上“调整对象大小”的按钮 - 并说明为什么会出现此问题。

此方法将生成驱动该按钮的代码。

但是，它不会自动更新 - 它是一个快照，只能在部署应用程序之前立即使用（如果最终用户将拥有按钮功能）。

然后序列变为：

  1. 运行使用以下方法生成的代码
  2. 立即保存工作簿 - 这不会阻止字体更改继续发生
  3. 重新打开工作簿，问题已“解决”
Private Sub printAllActiveXSizeInformation()
    Dim myWS As Worksheet
    Dim OLEobj As OLEObject
    Dim obName As String
    Dim shName As String

    'you could easily set a for/each loop for all worksheets
    Set myWS = Sheet1

    shName = myWS.name

    Dim mFile As String
    mFile = "C:\Users\you\Desktop\ActiveXInfo.txt"


    Open mFile For Output As #1
    With myWS
        For Each OLEobj In myWS.OLEObjects
            obName = OLEobj.name

            Print #1, "'" + obName
            Print #1, shName + "." + obName + ".Left=" + CStr(OLEobj.Left)
            Print #1, shName + "." + obName + ".Width=" + CStr(OLEobj.Width)
            Print #1, shName + "." + obName + ".Height=" + CStr(OLEobj.Height)
            Print #1, shName + "." + obName + ".Top=" + CStr(OLEobj.Top)
            Print #1, "ActiveSheet.Shapes(""" + obName + """).ScaleHeight 1.25, msoFalse, msoScaleFromTopLeft"
            Print #1, "ActiveSheet.Shapes(""" + obName + """).ScaleHeight 0.8, msoFalse, msoScaleFromTopLeft"

        Next OLEobj
    End With

    Close #1

    Shell "NotePad " + mFile



End Sub

*注意：不幸的是，这也不会找到分组的对象。

于 2013-10-15T16:05:27.780 回答
1

唯一 100% 可靠的解决方法是关闭并重新启动 Excel（包括任何不可见的实例）。任何其他解决方案都有一些问题。

这就是我尽可能避免控制的原因之一。有关示例，请参见此处。

于 2014-12-10T15:33:57.817 回答
1

该模块由 EE 的 dlmille 创建于 2011 年 3 月 20 日

这是一个练习，在工作簿中存储 active-x 控件设置，在工作表的基础上，如果/当 Excel 变得“古怪”并且形状大小歪斜时保留它们的设置而 ListBox 有一个 IntegralHeight 属性，其副作用是 FALSE设置将防止该控件歪斜，虽然命令按钮具有诸如移动/调整单元格等属性，但其他控件并不那么优雅。

例程 setControlsOnSheet()：1) 为活动工作表上的每个 OLEObject (active-x) 控件获取 6 个常用控件设置，2) 将这些设置存储到字符串数组 sControlSettings() 中，以及 3) 添加/更新具有这些设置的已定义名称（隐藏）。

工作表上每个控件的定义名称是根据活动工作表名称和控件名称建立的（应该创建一个唯一的实例）

过程：用户创建将在工作表上的任何控件，并且在任何时候，都可以运行 setControlsOnSheet() 例程，以最初存储所有控件的设置、刷新这些设置或添加新设置（因为它对工作表上的每个控件执行此操作）。

应注意确保所有设置“看起来正确”（例如，Excel 尚未变得“古怪”，或者用户刚刚调整了他的多个控件并准备“保存”他们的设置。否则，任何尺寸不正确的控件的设置将被存储。

工作表激活的 ThisWorkbook 事件不会使这个例程过程变得密集，而是会“重新初始化”刚刚选择的工作表上存在的所有控件的所有设置。这样，工作表上的控制设置“恢复”到它们最近保存的设置，因此“永远？” 避免 Excel“古怪”调整大小的后果。

作为一个潜在的增强功能，这个应用程序可以作为插件的一部分嵌入到类模块中，从而将任何相关代码排除在用户“正常”编程环境之外。例如，工作表激活事件捕获将在类模块中捕获，而不是用户必须将其添加到他/她的 ThisWorkbook 模块中。

Const CONTROL_OPTIONS = "Height;Left;Locked;Placement;Top;Width" 'some potentially useful settings to store and sustain

Function refreshControlsOnSheet(sh As Object)'routine enumerates all objects on the worksheet (sh), determines which have stored settings, then refreshes those settings from storage (in the defined names arena)

Dim myControl As OLEObject
Dim sBuildControlName As String
Dim sControlSettings As Variant

For Each myControl In ActiveSheet.OLEObjects
    sBuildControlName = "_" & myControl.Name & "_Range" 'builds a range name based on the control name
    'test for existance of previously-saved settings
    On Error Resume Next
    sControlSettings = Evaluate(sBuildControlName) 'ActiveWorkbook.Names(sBuildControlName).RefersTo 'load the array of settings
    If Err.Number = 0 Then ' the settings for this control are in storage, so refresh settings for the control
        myControl.Height = sControlSettings(1)
        myControl.Left = sControlSettings(2)
        myControl.Locked = sControlSettings(3)
        myControl.Placement = sControlSettings(4)
        myControl.Top = sControlSettings(5)
        myControl.Width = sControlSettings(6)
    End If
    Err.Clear
    On Error GoTo 0
Next myControl      
End Function

Private Sub storeControlSettings(sControl As String)
Dim sBuildControlName As String
Dim sControlSettings(1 To 6) As Variant ' set to the number of control settings to be stored
Dim oControl As Variant

Set oControl = ActiveSheet.OLEObjects(sControl)

'store the settings to retain, so they can be reset on demand, thus avoiding Excel's resizing "problem"
'create array of settings to be stored, with order dictated by CONTROL_OPTIONS for consistency/documentation

sControlSettings(1) = oControl.Height
sControlSettings(2) = oControl.Left
sControlSettings(3) = oControl.Locked
sControlSettings(4) = oControl.Placement
sControlSettings(5) = oControl.Top
sControlSettings(6) = oControl.Width


sBuildControlName = "_" & sControl & "_Range" 'builds a range name based on the control name

Application.Names.Add Name:="'" & ActiveSheet.Name & "'!" & sBuildControlName, RefersTo:=sControlSettings, Visible:=False 'Adds the control's settings to the defined names area and hides the range name
End Sub


Public Sub setControlsOnSheet()
Dim myControl As OLEObject

If vbYes = MsgBox("If you click 'Yes' the settings for all controls on your active worksheet will be stored as they CURRENTLY exist. " & vbCrLf & vbCrLf _
                & "Are you sure you want to continue (any previous settings will be overwritten)?", vbYesNo, "Store Control Settings") Then

    For Each myControl In ActiveSheet.OLEObjects 'theoretically, one could manage settings for all controls of this type...
        storeControlSettings (myControl.Name)
    Next myControl

    MsgBox "Settings have have been stored", vbOKOnly
End If
Application.EnableEvents = True 'to ensure we're set to "fire" on worksheet changes
End Sub
于 2016-12-30T12:48:15.637 回答
0

评论和形状也存在类似的问题。一种解决方法是编写一个宏来记录未使用的工作表上每个对象的.Width和.Height属性以及工作表位置属性。然后编写第二个宏来按需重新建立这些属性。

于 2013-10-15T16:14:33.247 回答
0

我对按钮有几个问题，字体大小就是其中之一。我还调整了按钮的大小，并调整了其中的图片大小。我可以以编程方式将按钮大小更改回来，但找不到以这种方式更改图片大小的方法。我想我已经找到了这些问题的最终解决方案。

如果我从（在我的情况下） C:\Users{UserName}\AppData\Local\Temp\Excel8.0 中删除 MSForms.exd 文件，而您在屏幕分辨率下，您想查看其中的按钮，然后重新启动Excel，这些问题似乎消失了。对于其他应用程序，您可能需要删除其他 .exd 文件。他们之中有一些是：

C:\Users\[user.name]\AppData\Local\Temp\Excel8.0\MSForms.exd

C:\Users\[user.name]\AppData\Local\Temp\VBE\MSForms.exd

C:\Users\[user.name]\AppData\Local\Temp\Word8.0\MSForms.exd

PowerPoint 也有一个，但我似乎找不到相关的支持文档（据我所知，它并没有真正指出这些具体问题）

于 2015-01-23T21:07:02.090 回答
0

这在过去发生在我身上（在使用与我的 PC 的远程连接之后或同时），但我想出了一个解决方案来使用Workbook_WindowActivate事件调整命令按钮及其字体的大小（这可以通过“重置设置”来完成）我想也是按钮）。

无论如何，直到今天我再次使用远程连接并且两个命令按钮开始出现异常时，我认为一切都已解决。我发现这 2 个命令按钮的 Placement 属性设置为 2（对象随单元格移动），而我过去将其设置为 3（对象是自由浮动的）。

但在找到这个之前，我试图将按钮的字体大小设置为我想要的（通过属性窗口），但是 Windows 忽略了我使用的任何数字，直到我改变了按钮的高度......所有突然它读取了字体大小属性并相应地进行了调整。

我不确定放置属性是否真的是问题的一部分，但为了确定，我使用了 2 个解决方案：

(1)placement设置为3

(2) 我随事件触发的“自动调整大小”功能会Workbook_WindowActivate稍微增加按钮和字体大小，然后再将它们缩小到应有的大小。但也许解决方案（1）就足够了......我现在没有时间测试。这是我的Workbook_Activate活动的代码：

Worksheets(1).Shapes("CommandButton1").Top = 0
Worksheets(1).Shapes("CommandButton1").Left = 206.25
Worksheets(1).Shapes("CommandButton1").Width = 75
Worksheets(1).OLEObjects(1).Object.Font.Size = 10
Worksheets(1).Shapes("CommandButton1").Height = 21
Worksheets(1).Shapes("CommandButton1").Height = 18.75
Worksheets(1).OLEObjects(1).Object.Font.Size = 8

现在一切正常。过去花了一些时间在网上找到解决方案。我希望这将帮助至少一个人;-)

于 2014-02-16T05:34:39.217 回答
0

我认为@RuiHonori 有最好的答案，但是为了让我将所有工作表上的控件控制到我希望它们所在的位置——它们的大小恰好相同——我使用了这个：

Sub SizeControls()
    Dim myControl As OLEObject
    Dim WS As Worksheet
    For Each WS In ThisWorkbook.Worksheets
        For Each myControl In WS.OLEObjects
            myControl.Height = 42.75
            myControl.Width = 96
        Next myControl
    Next WS
End Sub
于 2017-09-13T14:15:53.523 回答
0

我准备了一个解决方案，它是 Rui Honorio 建议的变体。

我在工作表上放置了一个多列组合框。我的“存储”例程版本循环遍历工作表上的所有 OLE 对象（上述组合框除外）并记录名称和选定的属性。

然后，组合框是工作表的一个相当紧凑/嵌入的组件。它不占用父工作表（或任何其他工作表）上的任何单元格。它可以放置在一个不起眼的位置或完全隐藏。

然后，“刷新”例程的触发器或手动运行可以从组合框中的每个列表项中获取属性，并为每个控件重置它们。

我对微软没有修复这个错误感到非常惊讶和非常沮丧。 多年来，我一直与它断断续续地相遇！

于 2021-12-01T20:40:50.953 回答