3

我正在尝试使用数据库查询将查询输出打印到 CSV，但无法将输出输出到单独的行。怎么做？

这是代码：

use warnings;
use DBI;
use strict;
use Text::CSV;

#set up file
my $csv = Text::CSV->new ( { binary => 1 } )  # should set binary attribute.
             or die "Cannot use CSV: ".Text::CSV->error_diag ();

open my $fh, ">:encoding(utf8)", "new.csv" or die "new.csv: $!";

#set up query
my $dbh = DBI->connect("DBI:mysql:db", "name") or die ("Error:  $DBI::errstr");

my $sql = qq(select * from one_table join two_table using (primary_key));
my $query = $dbh->prepare($sql);
$query->execute;

#loop through returned rows of query and save each row as an array
while ( my (@row ) = $query->fetchrow_array ) {
    #print each row to the csv file
    $csv->print ($fh, [@row]);    
        # every line seems to be appended to same line in "new.csv"
        # tried adding "\n" to no avail 
    }
close $fh or die "new.csv: $!";

这一定是一个常见的用例，但找不到任何关于新行问题的信息。

4

3 回答 3

5

我假设你的问题是你所有的 CSV 数据都在同一行？

您应该eol在 CSV 对象中设置选项：

my $csv = Text::CSV->new ( {
         binary => 1,      # should set binary attribute.
         eol    => $/,     # end of line character
}) or die "Cannot use CSV: ".Text::CSV->error_diag ();

此字符将附加到 中的行尾print。您可能还考虑不要在每次迭代时都从 fetchrow 调用中复制值，因为print需要一个数组 ref。使用引用会更直接。

while (my $row = $query->fetchrow_arrayref) {
    ....
    $csv->print($fh, $row);
于 2013-10-13T21:13:50.527 回答
3

首先，您在行尾缺少分号

my $sql = qq(select * from one_table join two_table using (primary_key))

默认情况下，Text::CSV使用 的当前值$\，即行尾的输出记录分隔符。而且，默认情况下，它设置为undef，因此您不会打印任何分隔符。

您可以设置您的$csv对象

my $csv = Text::CSV->new({ binary => 1, eol => "\n" });

或者像这样显式打印换行符。请注意，无需将行提取到数组中，然后将其复制到匿名数组即可使其正常工作。fetchrow_arrayref将返回一个数组引用，您可以直接将其传递给print.

while (my $row = $query->fetchrow_arrayref) {
  $csv->print($fh, $row);
  print $fh "\n";
}
于 2013-10-13T22:10:19.103 回答
-1

试试这个 sql 查询

select * from one_table join two_table using (primary_key) 
INTO OUTFILE '/tmp/new.csv' FIELDS TERMINATED BY ',' ENCLOSED BY '"' LINES TERMINATED BY '\n'
于 2013-10-13T21:09:36.050 回答