1

我正在尝试解析 WMIC 的输出，然后获取 PID。

我的脚本如下：

@echo off

setLocal enableExtensions enableDelayedExpansion

FOR /F "tokens=1* delims=" %%A IN ('"wmic process where(name="java.exe") get ProcessID,commandline| FINDSTR /v "CommandLine" | FINDSTR "TestServer""') DO (
     set "line=%%A"
     @REM echo "%%A"
     for /F "tokens=* delims= " %%C in ("%%A") do (
         echo "%%C"
         echo "%%D"
  )
)

输出如下：

"java  com.test.TestServer                                       7560       "
"%D"
"java  com.test.TestServer                                       7380       "
"%D"

我的目标是获取进程 ID。

我已经尝试使用空间作为 FOR 循环中的分隔符。然而没有运气。

所以我的问题是如何格式化 WMIC 的列并获取这些列？

4

4 回答 4

2

WMIC 使用 SQL 语法的一个子集。%您可以使用 LIKE 运算符 with作为通配符，在功能上将 FINDSTR 测试放在 WMIC WHERE 子句中。由于是批处理脚本，所以%需要加倍。

由于 WMIC 输出中不再需要 CommandLine 值，因此解析出 ProcessID 要容易得多。我添加了 SessionID 以在末尾放置一个未使用的值，以便更容易解析该值，而不必担心 FOR /F 在将 WMIC unicode 输出转换为 ANSI 时以某种方式引入的不需要的回车符。

@echo off
setlocal
set "pid="
for /f "skip=1" %%A in (
  'wmic process where "name='java.exe' and commandline like '%%TestServer%%' and not commandline like '%%CommandLine%%'" get processid^, sessionid'
) do if not defined pid set "pid=%%A"

编辑以回应评论中的问题

WMIC unicode 的 FOR /F 转换还引入了不需要的行，这些行看起来是空的，但实际上包含一个回车符。在我上面的代码中，我假设您期望一行，所以我使用 IF DEFINED 来有效地忽略不需要的尾随“空白”行。

如果您期望多个值，则需要另一种方法。额外的 FOR /F 循环将删除不需要的回车符，因此这些行真正变为空并因此被忽略。根据您的评论，您似乎不再需要忽略包含“CommandLine”的命令行。

我不知道你需要对这些值做什么，所以下面的代码只是简单地回显每个值。我使用 SKIP=1 代替通过 FINDSTR 管道传输结果以避免标题行。

@echo off
for /f "skip=1" %%A in (
  'wmic process where "name='java.exe' and commandline like '%%TestServer%%'" get processid'
) do for /f %%B in ("%%A") do echo %%B
于 2013-10-13T22:54:04.457 回答
0

这在我的系统上可以获取单个运行进程的 PID。

@echo off
FOR /F %%A IN ('"wmic process where name="java.exe" get ProcessID,commandline |findstr [0-9] " ') DO echo "%%A"
pause
于 2013-10-13T21:51:54.833 回答
0

使用 tokens=* 时将忽略 delims 参数

由于您需要第三个令牌，您应该使用 token=3

于 2013-10-13T19:39:57.360 回答
0 
for /f "tokens=1*delims==" %%a in ('wmic process where 'name^="java.exe" AND CommandLine like "%%TestServer%%"' get ProcessID /format:list^|find /i "ProcessID"') do set "ProcessID=%%b"
echo %ProcessID%
于 2013-10-13T22:16:18.227 回答