3

这是一个代表现实世界物理单元的数据类型：

import qualified Prelude as P
import Prelude hiding ((+), (*), (/), (-), Int, pi)

data Int = Zero | Succ Int | Pred Int

data Unit :: Int -> Int -> Int -> * where
    U :: Double -> Unit m s kg

(+) :: Unit m s kg -> Unit m s kg -> Unit m s kg
(-) :: Unit m s kg -> Unit m s kg -> Unit m s kg
(*) :: Unit m1 s1 kg1 -> Unit m2 s2 kg2 -> Unit (Plus m1 m2) (Plus s1 s2) (Plus kg1 kg2)
(/) :: Unit m1 s1 kg1 -> Unit m2 s2 kg2 -> Unit (Minus m1 m2) (Minus s1 s2) (Minus kg1 kg2)

和 Show 实例：

instance Show (Unit m s kg) where
    show (U a) = show a

这样，我只能显示值而不显示类型（是时间还是速度或长度类型）。我想知道如何获取类型参数m，s，kg然后显示它？

完整的代码在这里。

4

1 回答 1

5

你需要更多的扩展：

{-# LANGUAGE PolyKinds, ScopedTypeVariables #-}

PolyKinds打开更多邪恶的类型黑客，并ScopedTypeVariables允许您在函数定义中引用绑定在实例头和类型签名中的类型变量。

然后我们可以写如下：

data Proxy a = Proxy

class IntRep (n :: Int) where
    natToInt :: Proxy (n :: Int) -> Integer
instance IntRep Zero where
    natToInt _ = 0
instance (IntRep n) => IntRep (Succ n) where
    natToInt _ = 1 P.+ (natToInt (Proxy :: Proxy n)) 
instance (IntRep n) => IntRep (Pred n) where
    natToInt _ = (natToInt (Proxy :: Proxy n)) P.- 1

Proxy结合PolyKinds让您可以引用n在IntRep. 对幻像类型进行计算的通常策略是只使用undefined :: t，但undefined有 kind*所以undefined :: Zero是 kind 不匹配。因为您定义Unit为Unit :: Int -> Int -> Int -> *而不是Unit :: * -> * -> * -> *这种额外的误导是必需的。

最后是Show实例：

instance (IntRep m, IntRep s, IntRep kg) => Show (Unit m s kg) where
    show (U a) = unwords [show a, "m^" ++ u0, "s^" ++ u1, "kg^" ++ u2] 
        where u0 = show $ natToInt (Proxy :: Proxy m) 
              u1 = show $ natToInt (Proxy :: Proxy s)
              u2 = show $ natToInt (Proxy :: Proxy kg)

和

Prelude> main
0.1 m^1 s^-1 kg^0

补充阅读：http ://comments.gmane.org/gmane.comp.lang.haskell.glasgow.user/22159

于 2013-10-13T05:47:26.543 回答