5

给定以下 XML：

<results name="queryResults">
  <int name="intfield1:[* TO 10]">11</int> 
  <int name="intfield2:[10 TO 20]">9</int> 
  <int name="intfield1:[10 TO 20]">12</int> 
</results>

我想生成这个 XML：

<results>
    <field name="numberfield1">
        <value name="[* TO 10]">11</value>
        <value name="[10 TO 10]">12</value>
    </field>
    <field name="numberfield2">
        <value name="[10 TO 20]">9</value>
    </field>
</results>

我想不出如何在 XSL 中执行此操作，主要是因为我想按数字字段分组。我能想到的是：

<xsl:if test="count(results/int) &gt; 0">
    <results>
    <xsl:for-each select="results/int">
        <field>
            <xsl:attribute name="name">
                <xsl:value-of select="substring-before(@name, ':')"/></xsl:attribute>
            <value>
                <xsl:attribute name="name">
                    <xsl:value-of select="substring-after(@name, ':') "/>
                </xsl:attribute>
                <xsl:value-of select="."/>
            </value>
        </field>
    </xsl:for-each>
    </results>
</xsl:if>

但是，这不会产生漂亮的分组列表，而是我得到了这个：

<results>
    <field name="numberfield1">
        <value name="[* TO 10]">11</value>
    </field>
    <field name="numberfield2">
        <value name="[10 TO 20]">9</value>
    </field>
    <field name="numberfield1">
        <value name="[10 TO 10]">12</value>
    </field>
</results>

如果有人可以引导我朝着正确的方向前进.. 那会很棒吗？

谢谢

4

2 回答 2

12

要在 XSLT 1.0 中做到这一点，您必须使用一种称为“muenchian grouping”的技术。首先创建要分组的节点的密钥

<xsl:key name="intfield" match="int" use="substring-before(@name, ':')" />

接下来，遍历所有节点，但只选择恰好在相关组中排在第一位的节点

<xsl:for-each select="int[generate-id() = generate-id(key('intfield', substring-before(@name, ':'))[1])]">

接下来，您可以迭代使用密钥来迭代组中的所有节点

<xsl:variable name="intfieldname" select="substring-before(@name, ':')"/>
<xsl:for-each select="key('intfield', $intfieldname)">

把这一切放在一起给出

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
   <xsl:output method="xml"/>
   <xsl:key name="intfield" match="int" use="substring-before(@name, ':')"/>
   <xsl:template match="/results">
      <results>
         <xsl:for-each select="int[generate-id() = generate-id(key('intfield', substring-before(@name, ':'))[1])]">
            <xsl:variable name="intfieldname" select="substring-before(@name, ':')"/>
            <field>
               <xsl:attribute name="name">
                  <xsl:value-of select="$intfieldname"/>
               </xsl:attribute>
               <xsl:for-each select="key('intfield', $intfieldname)">
                  <value>
                     <xsl:attribute name="name">
                        <xsl:value-of select="substring-after(@name, ':')"/>
                     </xsl:attribute>
                     <xsl:value-of select="."/>
                  </value>
               </xsl:for-each>
            </field>
         </xsl:for-each>
      </results>
   </xsl:template>
</xsl:stylesheet>

在你的例子中，'intfield' 变成了 'numberfield'。在上面的示例中，我将名称保留为“intfield”。

  • 固定错字。
于 2009-12-18T16:26:37.350 回答
3

Muenchian 分组是天才的作品。这并不容易理解，但请参阅：http: //www.jenitennison.com/xslt/grouping/muenchian.html

为了简化流程，W3C 在 XSLT2.0 中特别支持分组。参见，例如： http ://www.xml.com/pub/a/2003/11/05/tr.html

然而，并非所有环境都支持 XSLT2.0

于 2009-12-20T12:55:46.947 回答