4

我有一个包含一大堆数据的电子表格（气象站目录），它计算最接近用户输入纬度和经度的气象站。此工作表通过计算与输入点的距离，使用 SMALL() 对这些距离进行排名，然后使用公式执行 Index(Match()) 类型计算（1 是最接近的，2 是第二接近的等）来实现这一点.

工作表虽然速度很慢，但效果相当好 - excel表格允许按照各种标准（例如记录长度等）对气象站目录进行高级排序。

我有一个我正在编写的 VBA 宏，它曾经可以工作，但是当我尝试修复它时停止工作（太棒了）。

VBA 宏的目的是编写一个带有纬度/经度/气象站名称的 Google 地球 KML 文件，然后将该文件启动到 google earth 中，以便用户可以可视化设置站点位置周围的邻近站点（先前输入的站点）由用户）。

不幸的是，我使用的原始方法无法处理列表的过滤结果，因此如果用户过滤结果（例如前 4 个气象站被过滤掉），宏仍然会写入前四个气象站不可见/已过滤。

对我来说这个问题变得更加困难，因为我希望只有一个宏用于四个带有可过滤表的工作表 - 用于不同的数据类型。

在这个阶段，宏需要的数据存储在不同工作表中同名表列中的表中：{"STATION","LONGITUDE","LATITUDE"}。写入 KML 文件所需的大部分 KML 字符串都存储在另一个隐藏的工作表“KML”中。

宏通过每个页面上的按钮启动。

我知道可能有一个使用“.SpecialCells(xlCellTypeVisible)”的解决方案 - 我已经广泛尝试让它与我的表格一起使用 - 但到目前为止没有运气 - 可能是由于我缺乏正规培训。

任何帮助表示赞赏，无论是解决方案还是建议！为我的错误代码道歉，问题循环和损坏的代码区域大约下降了一半 - 在“在活动工作表上查找所有表”之后：

Sub KML_writer()
Dim FileName As String
Dim StrA As String
Dim NumberOfKMLs
Dim MsgBoxResponse
Dim MsgBoxTitle
Dim MsgBoxPrompt
Dim WhileCounter
Dim oSh As Worksheet
    Set oSh = ActiveSheet
'Prompt the Number of Stations to Write to the KML File
NumberOfKMLs = InputBox(Prompt:="Please Enter the number of Weather Stations to generate within the Google Earth KML file", _
                Title:="Number of Weather Stations", Default:="10")
'Prompt a File Name
FileName = InputBox(Prompt:="Please Enter a name for your KML File.", _
                Title:="Lat Long to KML Converter", Default:="ENTER FILE NAME")

'Will clean this up to not require Write to Cell and Write to KML duplication later
Sheets("kml").Range("B3").Value = FileName
Sheets("mrg").Range("C5").Value = "Exported from EXCEL by AJK's MRG Function"

saveDir = "H:\" 'Local Drive available for all users of macro

targetfile = saveDir & FileName & ".KML"

'Write Site Location to KML STRING - user entered values from SITE LOCATION worksheet
StrA = Sheets("kml").Range("B1").Value & Sheets("kml").Range("B2").Value & "SITE LOCATION" & Sheets("kml").Range("B4").Value & Sheets("INPUT COORDINATES").Range("E5").Value & Sheets("kml").Range("B6").Value & Sheets("INPUT COORDINATES").Range("E4").Value & Sheets("kml").Range("B8").Value

    'Find all tables on active sheet
    Dim oLo As ListObject
    For Each oLo In oSh.ListObjects

'
        Dim lo As Excel.ListObject
        Dim lr As Excel.ListRow
        Set lo = oSh.ListObjects(oLo.Name)
        Dim cl As Range, rng As Range
        Set rng = Range(lo.ListRows(1))  'this is where it breaks currently

    For Each cl In rng2    '.SpecialCells(xlCellTypeVisible)


'Stop looping when NumberofKMLs is written to KML
            WhileCounter = 0
            Do Until WhileCounter > (NumberOfKMLs - 1)
            WhileCounter = WhileCounter + 1

                Dim St
                Dim La
                Dim Lon


                'Store the lr.Range'th station data to write to the KML
                St = Intersect(lr.Range, lo.ListColumns("STATION").Range).Value
                La = Intersect(lr.Range, lo.ListColumns("LATITUDE").Range).Value
                Lon = Intersect(lr.Range, lo.ListColumns("LONGITUDE").Range).Value


                'Write St La Long & KML Strings for Chosen Stations
                StrA = StrA & Sheets("kml").Range("B2").Value & St & Sheets("kml").Range("B4").Value & Lon & Sheets("kml").Range("B6").Value & La & Sheets("kml").Range("B8").Value

        Loop
        Next
        Next

'Write end of KML strings to KML File
StrA = StrA & Sheets("kml").Range("B9").Value

'Open, write, close KML file
Open targetfile For Output As #1
Print #1, StrA
Close #1

'Message Box for prompting the launch of the KML file
MsgBoxTitle = ("Launch KML?")
MsgBoxPrompt = "Would you like to launch the KML File saved at " & targetfile & "?" & vbCrLf & vbCrLf & "Selecting 'No' will not prevent the file from being written."
MsgBoxResponse = MsgBox(MsgBoxPrompt, vbYesNo, MsgBoxTitle)
If MsgBoxResponse = 6 Then ThisWorkbook.FollowHyperlink targetfile

End Sub
4

2 回答 2

14

这是一个对过滤表进行迭代的示例。这使用的ListObject表格比仅像表格一样排列的一系列自动过滤单元格更容易使用，但是可以使用相同的一般想法（除非您不能调用DataBodyRange非ListObject表格）。

创建表：

未过滤的表

对其应用一些过滤器：

过滤表

请注意，已经隐藏了几行，可见行不一定是连续的，因此我们需要使用可见的.Areas表。DataBodyRange

正如您已经推测的那样，您可以使用.SpecialCells(xlCellTypeVisible)来执行此操作。

这是一个例子：

Sub TestFilteredTable()

   Dim tbl As ListObject
   Dim rngTable As Range
   Dim rngArea As Range
   Dim rngRow As Range

   Set tbl = ActiveSheet.ListObjects(1)
   Set rngTable = tbl.DataBodyRange.SpecialCells(xlCellTypeVisible)

   ' Here is the address of the table, filtered:
   Debug.Print "Filtered table: " & rngTable.Address

   '# Here is how you can iterate over all
   '  the areas in this filtered table:
   For Each rngArea In rngTable.Areas
      Debug.Print "  Area: " & rngArea.Address

         '# You will then have to iterate over the
         '  rows in every respective area
         For Each rngRow In rngArea.Rows
            Debug.Print "    Row: " & rngRow.Address
         Next
   Next

End Sub

样本输出：

Filtered table: $A$2:$G$2,$A$4:$G$4,$A$6:$G$6,$A$9:$G$10
  Area: $A$2:$G$2
    Row: $A$2:$G$2
  Area: $A$4:$G$4
    Row: $A$4:$G$4
  Area: $A$6:$G$6
    Row: $A$6:$G$6
  Area: $A$9:$G$10
    Row: $A$9:$G$9
    Row: $A$10:$G$10

尝试根据您的问题调整此方法，如果您在实施时遇到特定错误/问题，请告诉我。
请记住更新您的原始问题以指示更具体的问题:)

于 2013-10-10T01:39:32.913 回答
0

我必须在过滤数据中找到一条记录并更改一个值 示例数据

我想将销售人员代码更改为客户 C00005。

首先，我过滤并找到要修改的客户。

codcliente = "C00005"


enter  'make sure that this customer exist in the checked range


 Set test = CheckRng.Find(What:=codcliente, LookIn:=xlValues, LookAt:=xlWhole)
  If test Is Nothing Then
    MsgBox ("Does not exist customer  """ & codcliente & """ !")
    DataSheet.AutoFilterMode = False
  Else 'Customer Exists
    With DataRng 'filter the customer
        .AutoFilter Field:=1, Criteria1:=codcliente
    End With
   Set customer = DataRng.SpecialCells(xlCellTypeVisible) ´Get customer data. It is visible
   customer.Cells(1, 6).Value = "NN" 'navigate to 6th column and change code
End If

在此处输入图像描述

于 2016-02-19T16:56:42.393 回答