1

标题是不言自明的，但这是我想做的图片。我很难弄清楚它是否可能。

示例豆图

图借自： 硫化矿周围地球化学背景水平的评估——一种带有豆状图的新统计程序。古斯塔瓦森等人。2012 年。

4

1 回答 1

3

如果可能的话，完全按照这个方向进行绘图可能会非常麻烦。

我的建议是以通常的方向绘制所有内容（即，将“沉积物”轴作为 -x轴，或者更确切地说作为x2- 轴），稍微旋转所有标签，最后按90度旋转完整的输出（带有例如等的 pdf 文件pdftk）。

有了这个，您可以像往常一样使用任何绘图样式。在下面的脚本中，我只是向您展示了如何为两个不同的数据集绘制紫色和黄色填充曲线（使用伪数据）。添加其他峰应该是直截了当的（使用例如boxes或vector绘图样式绘制条形图）。

为了ytics使不同的图有区别，我将某个y值与某个图相关联1=Water，...，4=Gyttja）。

将所有内容放在一起给出以下脚本：

reset
set terminal pdfcairo linewidth 2
outfile='bean'
set output outfile.'.pdf'
set encoding utf8

set x2range [0.5:9000]
set logscale x2
set x2tics (1, 5, 10, 50, '' 100, 500, '' 1000, 5000) out
set x2label 'mg/kg (sediments), µg/L (water)'
unset xtics

set yrange[0.5:4.5]
set ytics ('Water' 1, 'Minerogenic' 2, 'Peat' 3, 'Gyttja' 4) center rotate by -90 out

set label at graph 0.95, graph 0.05 right rotate by -90 'Nickel' font ',20' front
# cover possible data overlapping with the label
set object rectangle from graph 0.9, graph 0 to graph 1,graph 0.2 fillcolor rgb 'white' fillstyle solid noborder front

unset key

set macros
fs1="fillcolor rgb '#fc9e00' linewidth 2 fillstyle solid border lt -1"
fs2="fillcolor rgb '#9119f7' linewidth 2 fillstyle solid border lt -1"
# use pseudo data
set samples 500
plot '+' using 1:(4-0.3*exp(-(($1-10)/5.0)**4)) axes x2y1 with filledcurves y1=4 @fs1,\
     '' using 1:(4+0.2*exp(-(($1-70)/50.0)**4)) axes x2y1 with filledcurves y1=4 @fs2,\
     '' using 1:(1-0.4*exp(-(($1-5)/2.0)**2)) axes x2y1 with filledcurves y1=1 @fs1,\
     '' using 1:(1+0.1*exp(-(($1-30)/20.0)**2)) axes x2y1 with filledcurves y1=1 @fs2

set output
system(sprintf('pdftk %s.pdf cat 1W output %s-rot.pdf', outfile, outfile))
system(sprintf('pdftocairo -r 150 -png %s-rot.pdf', outfile))

这与 4.6.3 给出（常规和旋转输出并排）：

在此处输入图像描述

伪数据需要一些东西。对于真实的数据文件，绘图线看起来有点不同。不同的图有一个分离的1方向y，所以你必须相应地缩放你的数据（在这里用缩放因子手动完成sc）：

sc = 5.1
plot 'datafile.txt' using 1:(4 + $2/sc) axes x2y1 with filledcurves y1=4 @fs1

stats您当然也可以通过使用命令提取一些最小/最大值来自动进行缩放。

于 2013-10-09T08:27:49.817 回答