12

考虑以下：

do
  x1 <- new 2
  set x1 3
  x2 <- get x1
  y1 <- new 10
  set y1 20
  y2 <- get y1
  return (x2 + y2)

我希望这会导致23. 有没有办法在纯 Haskell 中实现这样的东西，如果是这样，怎么做？我明白STRef会做这样的事情，但我只想用普通的 Haskell 来做（目前不担心效率）。我想我必须创建一个数据类型并使其成为 的实例Monad，但我不确定细节，所以一个工作示例会很有帮助。

4

4 回答 4

6

这允许多个值，但它更复杂:) 这很好地简化了丹尼尔的建议Dynamic。

import Data.Dynamic
import Data.Maybe
import Control.Monad.State
import Data.Map as M

newtype Ref a = Ref {ref :: Int}

type MutState = State (Int, Map Int Dynamic)

val :: Typeable a => Ref a -> MutState a
val r = snd `fmap` get >>= 
        return . fromJust . (>>= fromDynamic) .  M.lookup (ref r)

new :: Typeable a => a -> MutState (Ref a)
new a = do
  (curr, binds) <- get
  put (curr + 1, M.insert (curr + 1) (toDyn a) binds)
  return . Ref $ curr + 1

set :: Typeable a => Ref a -> a -> MutState ()
set (Ref i) a = do
  (c, m) <- get
  put (c, M.insert i (toDyn a) m)

runMut :: MutState a -> a
runMut = flip evalState (0, M.fromList [])

然后使用它

default (Int) -- too lazy for signatures :)
test :: Int
test = runMut $ do
  x1 <- new 2
  set x1 3
  x2 <- val x1
  y1 <- new 10
  set y1 20
  y2 <- val y1
  return (x2 + y2)

Refs 基本上Int是 s 附加了一些类型信息，并且val会查找适当的Dynamic并尝试将其强制转换为正确的类型。

如果这是真实代码，您应该隐藏 和 的Ref实现MutState。为方便起见，如果您想要一个安全的实现，我已经fromJust编辑了 bur 的返回值，我想您可以分层和单子来处理未绑定的变量。valStateMaybe

如果您担心可键入的约束，如上所示，它们是微不足道的。

于 2013-10-07T15:02:36.957 回答
5

中已经有一个实现Control.Monad.State，但为了通用性，它很麻烦：一个复杂性来自 MonadState 类，另一个来自于 plainState以更通用的形式实现的事实StateT。

这是使用该实现的任务示例。没有使用可变性。请注意，您的示例按原样粘贴，只需添加x前缀：

import Control.Monad.State
import qualified Data.Map as M

type MyMap a = M.Map Int a
type MyState a b = State (MyMap a) b
type MyRef = Int

xrun :: MyState a b -> b
xrun x = evalState x (M.empty)

mget :: MyState a (MyMap a)
mget = get

mput :: MyMap a -> MyState a ()
mput = put

mmodify :: (MyMap a -> MyMap a) -> MyState a ()
mmodify x = modify x

xnew :: s -> MyState s MyRef
xnew val = do
    s <- mget
    let newRef = if M.null s then 0 else fst (M.findMax s) + 1
    mput $ M.insert newRef val s
    return newRef

xset :: MyRef -> a -> MyState a () 
xset ref val = modify $ M.insert ref val

xget :: MyRef -> MyState a a
xget ref = fmap (\s -> case M.lookup ref s of Just v -> v) get

test :: MyState Int Int
test = do
  x1 <- xnew 2
  xset x1 3
  x2 <- xget x1
  y1 <- xnew 10
  xset y1 20
  y2 <- xget y1
  return (x2 + y2)

main = print $ xrun test

可以实现模块中的所有功能和>>=/return而不使用Control.Monad保留签名的库存实现。

这里是：

module MyState (State, get, put, modify, evalState) where

newtype State s a = State (s -> (a, s))

evalState :: State s a -> s -> a
evalState (State f) = fst . f

instance Monad (State s) where
    return a = State $ \s -> (a, s)
    State f >>= g = State $ \s -> 
        case f s of 
            (a', s') -> case g a' of 
                State h -> h s'

instance Functor (State s) where
    fmap f (State g) = State $ 
        \s -> case g s of (a, s) -> (f a, s) 

get :: State s s
get = State (\s -> (s, s))

put :: s -> State s ()
put s = State $ \_ -> ((), s)

modify :: (s -> s) -> State s ()
modify f = get >>= put . f

将其保存MyState.hs并替换import Control.Monad.State为import MyState.

于 2013-10-07T14:51:08.497 回答
2

使用State或者StateT您可以模拟它（State只允许 1 个值）。最简单的方法是使用Map：

 do
  put empty
  set "x1" 3  
  x2 <-  getKey "x1"
  set "y1" 20
  y2 <-  getKey "y1"
  return (x2 + y2)
    where
      getKey k = fromJust . (lookup k) `fmap` get
      set = modify replace
      replace d k m = if k `member` m then update (\_ -> Just d) k m
                      else insert k d m
于 2013-10-07T14:56:19.640 回答
2

元组的 StateT 怎么样？

flip evalState (2, 10) $ do
  modify $ \(_, y) -> (3, y)
  x2 <- fst <$> get
  modify $ \(x, _) -> (x, 20)
  y2 <- snd <$> get
  return (x2 + y2)

如果你真的想要可变单元格，我建议使用 ST、STM 或 IO 而不是 StateT。在从增加自然到对象的异构映射上使用 StateT 的实现似乎是可能的，但可能有点尴尬。

于 2013-10-17T15:58:51.733 回答