4

使用query-replace，迷你缓冲区会这样说（保存了前面的参数）：

Query replace (default FROM -> TO)

有没有交换参数的命令？要得到这个：

Query replace (default TO -> FROM)
4

4 回答 4

3

AFAIK，开箱即用的任何东西都不会为您做到这一点。但恕我直言，你不需要那个。

您需要做的就是使用M-p. 使用一次即可获得最后一次TO使用。然后重复M-p几次以获得FROM您使用的最后一个。很快。

之后，您可以使用C-x ESC ESC（或C-x M-:或C-x M-ESC），可能后跟M-p，重复任一组合（TO -> FROM或FROM -> TO）。

于 2013-10-04T19:59:22.897 回答
1

有一个交换参数的捷径：M-p RET M-p M-p RET

于 2013-10-05T16:32:57.803 回答
1

我用这个：

;; Redefine `query-replace-read-from' to add a custom keymap when
;; replacing strings. Now, C-u ENTER does the reverse suggested
;; replacement.
(defvar query-replace-keymap
  (let ((map (make-sparse-keymap)))
    (set-keymap-parent map minibuffer-local-map)
    (define-key map [remap exit-minibuffer]
      (lambda ()
        (interactive)
        (if (and current-prefix-arg query-replace-defaults)
            (setq query-replace-defaults
                  (cons
                   (cdr query-replace-defaults)
                   (car query-replace-defaults))))
        (exit-minibuffer)))
    map))

(defun query-replace-read-from (prompt regexp-flag)
  "Query and return the `from' argument of a query-replace operation.
The return value can also be a pair (FROM . TO) indicating that the user
wants to replace FROM with TO."
  (if query-replace-interactive
      (car (if regexp-flag regexp-search-ring search-ring))
    (let* ((history-add-new-input nil)
           (query-replace-defaults query-replace-defaults)
           (prompt
            (if query-replace-defaults
                (format "%s (default %s -> %s): " prompt
                        (query-replace-descr (car query-replace-defaults))
                        (query-replace-descr (cdr query-replace-defaults)))
              (format "%s: " prompt)))
           (from
            ;; The save-excursion here is in case the user marks and copies
            ;; a region in order to specify the minibuffer input.
            ;; That should not clobber the region for the query-replace itself.
            (save-excursion
              (if regexp-flag
                  (read-regexp prompt nil query-replace-from-history-variable)
                (read-from-minibuffer
                 prompt nil query-replace-keymap nil query-replace-from-history-variable
                 (car (if regexp-flag regexp-search-ring search-ring)) t)))))
      (if (and (zerop (length from)) query-replace-defaults)
          (cons (car query-replace-defaults)
                (query-replace-compile-replacement
                 (cdr query-replace-defaults) regexp-flag))
        (add-to-history query-replace-from-history-variable from nil t)
        ;; Warn if user types \n or \t, but don't reject the input.
        (and regexp-flag
             (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\(\\\\[nt]\\)" from)
             (let ((match (match-string 3 from)))
               (cond
                ((string= match "\\n")
                 (message "Note: `\\n' here doesn't match a newline; to do that, type C-q C-j instead"))
                ((string= match "\\t")
                 (message "Note: `\\t' here doesn't match a tab; to do that, just type TAB")))
               (sit-for 2)))
        from))))
于 2013-10-05T21:15:25.960 回答
1 
(defun swap-query-replace-defaults ()
  "Swap the initial expressions offered by `query-replace'. "
  (interactive)
  (let* ((erg query-replace-defaults)
         (first (car erg))
         (second (cdr erg)))
    (setq query-replace-defaults (cons second first))
    (when (interactive-p) (message "%s" query-replace-defaults))
    query-replace-defaults))

提出了功能要求：

http://lists.gnu.org/archive/html/bug-gnu-emacs/2013-10/msg00102.html

于 2013-10-05T07:15:37.560 回答