1

我正在运行时创建一个 Excel 文档，其中包含一堆我希望有条件地格式化的值。在从头开始进行各种尝试以及使用/修改从 Excel 的宏记录器输出的代码时，我遇到了与格式覆盖相关的一致问题。

我在下面发布了一段代码，可以说我已经测试过，以确保我的选择范围是有效的，并且适合我想要有条件地格式化的内容。有一些重叠，但奇怪的是第一种条件格式只具有第二种条件格式的一个属性。含义 D5：工作表的结尾最终具有绿色字体，而不是应有的红色。评论代码的每个部分确实允许它们独立工作，但我猜这是以某种方式进一步指定条件格式的问题？我尝试了几种不同的情况，下面是经过修改的代码：

编辑（更新代码）：

'First conditional format, check sheet for values > 50 and make text red.
With xl.range("D5:" & theLastColumn & lastRow)
  .FormatConditions.add Type:=xlCellValue, Operator:=xlGreater, Formula1:="=50"
  With .FormatConditions(1).Font
    .Color = -16383844
    .TintAndShade = 0
  End With
  .FormatConditions(1).StopIfTrue = False
End With


'Second conditional format, check specific row (row 5 in the example) 
'for values > 40, and fill interior with green in addition to dark green text.
With xl.range("D" & Infectivity & ":" & theLastColumn & Infectivity)
  .FormatConditions.add Type:=xlCellValue, Operator:=xlGreater, Formula1:="=40"
  With .FormatConditions(2).Font
    .Color = -16752384
    .TintAndShade = 0
  End With
  With .FormatConditions(2).Interior
    .PatternColorIndex = xlAutomatic
    .Color = 13561798
    .TintAndShade = 0
  End With
End With

那么拥有多种条件格式（可能重叠范围）并且仍然让它们都按预期运行的最佳方法是什么？我已经尝试过很多次调试，我确信我忽略了一些简单的东西。我还尝试了几种不同的方法来指定单独的 formatconditions(1) 和 formatconditions(2)，但仍然收到奇怪的问题。

编辑：

我继续遇到同样问题的 VBA 代码。

Sub conditionalFormat()
  With Range("D5:BA9")
    .FormatConditions.Add Type:=xlCellValue, Operator:=xlGreater, Formula1:="=50"
    .FormatConditions(.FormatConditions.Count).SetFirstPriority
    With .FormatConditions(1).Font
      .Color = -16383844
      .TintAndShade = 0
    End With
    .FormatConditions(1).StopIfTrue = False
  End With

  With Range("D9:BA9")
    .FormatConditions.Add Type:=xlCellValue, Operator:=xlGreater, Formula1:="=40"
    With .FormatConditions(2).Font
      .Color = -16752384
      .TintAndShade = 0
    End With
    With .FormatConditions(2).Interior
      .PatternColorIndex = xlAutomatic
      .Color = 13561798
      .TintAndShade = 0
    End With
    .FormatConditions(2).StopIfTrue = False
  End With    
End Sub

即使使用适当的（红色文本）条件格式的 SetFirstPriority，它也会以某种方式被覆盖。我在这里错过了什么吗？

4

2 回答 2

1

对不起。我没有 Excel 2007。在 Excel 2010 中对此进行了测试。

当谈到条件格式时，您必须非常小心宏记录器吐出的内容。这是一种使代码混乱的特殊情况。

此外，您将第二条规则设置.SetFirstPriority为不正确，除了让第二条规则运行，尽管rule 1得到满足:)

这是一个非常基本的例子。假设我的范围看起来像这样D5:G7

在此处输入图像描述

现在这是我测试的 VBA 代码

Sub Sample()
    Dim ws As Worksheet
    Dim rng As Range

    Set ws = ThisWorkbook.Sheets("Sheet1")
    Set rng = ws.Range("D5:G7")

    With rng
        .FormatConditions.Add Type:=xlCellValue, _
        Operator:=xlGreater, Formula1:="=50"
        .FormatConditions(.FormatConditions.Count).SetFirstPriority
        With .FormatConditions(1).Font
            .Color = -16776961
            .TintAndShade = 0
        End With
        .FormatConditions(1).StopIfTrue = True

        .FormatConditions.Add Type:=xlCellValue, _
        Operator:=xlGreater, Formula1:="=40"
        With .FormatConditions(2).Font
            .Color = -11489280
            .TintAndShade = 0
        End With
        With .FormatConditions(2).Interior
            .PatternColorIndex = xlAutomatic
            .ThemeColor = xlThemeColorAccent3
            .TintAndShade = 0.599963377788629
        End With
    End With
End Sub

这就是我得到的结果。

在此处输入图像描述

我相信您将上述代码移植到 vb6 会非常容易。

后续行动（来自评论）

使用后期绑定...早期绑定是否更适合进行这种类型的条件格式化？– 伯纳德 2 分钟前

如果您使用的是 LateBinding，请在代码顶部声明此代码

Const xlCellValue as Long = 1
Const xlGreater as Long = 5
Const xlAutomatic as Long = -4105
Const xlThemeColorAccent3 as Long = 7
于 2013-10-04T16:36:50.040 回答
0

经过深思熟虑和修改代码，我们得出结论，我正在做的事情（多个条件重叠）是导致混合结果的原因。在最简单的级别上，我能够将 .FormatConditions.Delete 添加到我的其他条件格式中，以确保只应用一种格式。

修正后的最终代码如下所示：

Dim Infectivity As Long
Infectivity = Application.WorksheetFunction.match("Infectivity", range("A1:" & "A" & lastRow), 0)

With xl.range("D5:" & theLastColumn & lastRow)
    .FormatConditions.add Type:=xlCellValue, Operator:=xlGreater, _
    Formula1:="=50"
    .FormatConditions(.FormatConditions.count).SetFirstPriority
With .FormatConditions(1).Font
    .Color = -16383844
    .TintAndShade = 0
End With

    .FormatConditions(1).StopIfTrue = False
End With

If Infectivity > 0 Then
With xl.range("D" & Infectivity & ":" & theLastColumn & Infectivity)
    .FormatConditions.Delete
    .FormatConditions.add Type:=xlCellValue, Operator:=xlGreater, _
     Formula1:="=40"
With .FormatConditions(1).Font
    .Color = -16752384
    .TintAndShade = 0
End With
With .FormatConditions(1).Interior
    .PatternColorIndex = xlAutomatic
    .Color = 13561798
    .TintAndShade = 0
End With
.FormatConditions(1).StopIfTrue = False
End With
End If

我的失败与宏记录器有关，它给了我一个错误的格式化这些单元格的理想方法。在继续前进之前，最好先简化。

非常感谢 Siddharth Rout 的所有帮助。

于 2013-10-04T20:39:04.143 回答