4

您好我正在尝试使用 glDrawArraysInstanced() 渲染许多轴对齐的立方体。每个固定大小的立方体只能在其中心位置和颜色上有所不同。此外，每个立方体只需要几种不同的颜色。所以我想用以下每个实例数据潜在地渲染数百万个立方体：

struct CubeInfo {
  Eigen::Vector3f center; // center of the cube (x,y,z)
  int labelId;  // label of the cube which affects its color
};

所以我使用以下顶点着色器：

#version 330

uniform mat4 mvp_matrix;

//regular vertex attributes
layout(location = 0) in vec3 vertex_position;

// Per Instance variables
layout(location = 1) in vec3 cube_center;
layout(location = 2) in int cube_label;

// color out to frag shader
out vec4 color_out;

void main(void) {
  // Add offset cube_center
  vec4 new_pos = vec4(vertex_position + cube_center, 1);
  // Calculate vertex position in screen space
  gl_Position = mvp_matrix * new_pos;

  // Set color_out based on label
  switch (cube_label) {
  case 1:
    color_out = vec4(0.5, 0.25, 0.5, 1);
    break;
  case 2:
    color_out = vec4(0.75, 0.0, 0.0, 1);
    break;
  case 3:
    color_out = vec4(0.0, 0.0, 0.5, 1);
    break;
  case 4:
    color_out = vec4(0.75, 1.0, 0.0, 1);
    break;
  default:
    color_out = vec4(0.5, 0.5, 0.5, 1); // Grey
    break;
  }
}

和相应的片段着色器：

#version 330

in vec4 color_out;
out vec4 fragColor;

void main()
{
    // Set fragment color from texture
    fragColor = color_out;
}

然而 color_out 总是采用默认的灰度值，即使 cube_label 的值在 1 到 4 之间。这是我的问题。我在上面的着色器中做错了吗**？**

我用 1-4 之间的随机 labelIds 初始化了 cubeInfo vbo。所以我期待看到比以下更丰富多彩的输出： 在此处输入图像描述

这是我的渲染代码，它使用了 Qt 的QGLShaderProgram和QGLBuffer包装器：

  // Enable back face culling
  glEnable(GL_CULL_FACE);
  cubeShaderProgram_.bind();

  // Set the vertexbuffer stuff (Simply 36 vertices for cube)
  cubeVertexBuffer_.bind();
  cubeShaderProgram_.setAttributeBuffer("vertex_position", GL_FLOAT, 0, 3, 0);
  cubeShaderProgram_.enableAttributeArray("vertex_position");
  cubeVertexBuffer_.release();

  // Set the per instance buffer stuff
  cubeInstanceBuffer_.bind();

  cubeShaderProgram_.setAttributeBuffer("cube_center", GL_FLOAT, offsetof(CubeInfo,center), 3, sizeof(CubeInfo));
  cubeShaderProgram_.enableAttributeArray("cube_center");
  int center_location = cubeShaderProgram_.attributeLocation("cube_center");
  glVertexAttribDivisor(center_location, 1);

  cubeShaderProgram_.setAttributeBuffer("cube_label", GL_INT, offsetof(CubeInfo,labelId), 1, sizeof(CubeInfo));
  cubeShaderProgram_.enableAttributeArray("cube_label");
  int label_location = cubeShaderProgram_.attributeLocation("cube_label");
  glVertexAttribDivisor(label_location, 1);

  cubeInstanceBuffer_.release();

  // Do Instanced Renering
  glDrawArraysInstanced(GL_TRIANGLES, 0, 36, displayed_num_cubes_ );

  cubeShaderProgram_.disableAttributeArray("vertex_position");
  cubeShaderProgram_.disableAttributeArray("cube_center");
  cubeShaderProgram_.disableAttributeArray("cube_label");

  cubeShaderProgram_.release();

除了我上面的主要问题（颜色问题），这是做 Minecraft 的好方法吗？

更新 如果我将CubeInfo.labelId属性从更改int为float，并且相应的顶点着色器变量cube_label也更改为float，它可以工作！！。为什么会这样？这个页面说 GLSL 支持 int 类型。对我来说，我更喜欢 labelId/cube_label 是一些 int/short。

更新2：

即使我只是在渲染代码的下一行中更改为 GL_FLOAT 而不是 GL_INT，我也会得到正确的颜色。

cubeShaderProgram_.setAttributeBuffer("cube_label", GL_INT, offsetof(CubeInfo,labelId), 1, sizeof(CubeInfo));
4

2 回答 2

2

您的标签属性的问题是，它是一个整数属性，但您没有将其设置为整数属性。Qt 的setAttributeBuffer函数对整数属性一无所知，它们都glVertexAttribPointer在后台使用，它以任意格式获取顶点数据并将其转换为float以将其传递给与着色器in float不匹配的属性（因此in int属性可能只是保持在某个随机默认值，或者得到一些未定义的值）。

要将数据实际传递到一个真正的整数顶点属性（这与浮点属性完全不同，直到 GL 3+ 才引入），你需要这个函数glVertexAttribIPointer（注意I那里的和属性类似D，in double只是使用GL_DOUBLEwon'在这种情况下也不起作用）。但可悲的是，Qt 还没有真正适合 GL 3+，似乎没有一个包装器。因此，您要么必须手动使用：

glVertexAttribIPointer(cubeShaderProgram_.attributeLocation("cube_label"), 
                       1, GL_INT, sizeof(CubeInfo), 
                       static_cast<const char*>(0)+offsetof(CubeInfo,labelId));

而不是cubeShaderProgram_.setAttributeBuffer调用，或者使用in float属性来代替。

于 2013-10-06T10:36:40.827 回答
0

如果你想使用在顶点着色器中分配的颜色，你至少应该写一个简单的片段着色器，比如：

void main()
{
   gl_FragColor = color_out;
}

更新

我认为要么你不能将 cube_label 传递给你的顶点着色器，要么你没有首先设置它们（在结构中）。后一种可能性更大，但您可以用以下行替换您的 switch-case 以查看传递的实际值。

color_out = vec4(float(cube_label) / 4.0, 0, 0, 1.0);

更新2

一旦我遇到了与英特尔 GPU（驱动程序）类似的问题。无论我尝试什么都无法传递整数值。但是，相同的着色器在 NVIDIA 上完美运行，因此在您的情况下，我将 int 转换为 float。

于 2013-10-04T11:09:41.150 回答