oracle - 如何遍历 Oracle PLSQL 中的分隔列表

Question

我正在研究一个在其中调用另一个过程的 Oracle 过程。我的参数(parm1)之一可以在逗号分隔列表中包含一个或多个值。如何循环遍历这些值以一次将它们传递给另一个过程？

这是我想要它做的一个例子：

When Parm1 = 123,312

callProcedure2(123)
callProcedure2(321)

-或者-

When Parm1 123

callProcedure2(123)

我认为这可以使用循环来完成，但我不知道如何让它在循环中使用每个值作为单独的调用。

任何帮助，将不胜感激！

谢谢！

Answer 1

CURSOR V_CUR IS
select regexp_substr(Parm1 ,'[^,]+', 1, level) As str from dual
connect by regexp_substr(Parm1, '[^,]+', 1, level) is not null;

这个游标会给你这样的结果

123
321

现在迭代游标并循环调用过程。

For i IN V_CUR
LOOP
    callProdcedure2(i.str);
END LOOP;

Answer 2

只需遍历子字符串：

declare 
  parm1 varchar2(1000) := '123,234,345,456,567,789,890';

  vStartIdx binary_integer;
  vEndIdx   binary_integer;
  vCurValue varchar2(1000);
begin

  vStartIdx := 0;
  vEndIdx   := instr(parm1, ','); 

  while(vEndIdx > 0) loop
    vCurValue := substr(parm1, vStartIdx+1, vEndIdx - vStartIdx - 1);

    -- call proc here
    dbms_output.put_line('->'||vCurValue||'<-');

    vStartIdx := vEndIdx;
    vEndIdx := instr(parm1, ',', vStartIdx + 1);  
  end loop;

  -- Call proc here for last part (or in case of single element)
  vCurValue := substr(parm1, vStartIdx+1);
  dbms_output.put_line('->'||vCurValue||'<-');

end;

Answer 3

有专门用于此任务的实用程序COMMA_TO_TABLE和数组类型。DBMS_UTILITY.UNCL_ARRAY从Oracle 10g 开始。

这是很好的文件here。

这是一个示例解决方案：

SET SERVEROUTPUT ON
DECLARE
    csvListElm VARCHAR2(4000) := 'elm1, elm2,elm3 ,elm4 , elm5';
    csvListTable DBMS_UTILITY.UNCL_ARRAY;
    csvListLen BINARY_INTEGER;
    currTableName VARCHAR2(222);
BEGIN
    DBMS_UTILITY.COMMA_TO_TABLE(csvListElm, csvListLen, csvListTable);
    FOR csvElm IN 1..(csvListTable.COUNT - 1) LOOP
        dbms_output.put_line('-- CSV element        : <'||csvListTable(csvElm)||'>');
        dbms_output.put_line('-- Trimmed CSV element: <'||trim(csvListTable(csvElm))||'>');
    END LOOP; 
END;
/

样本输出：

-- CSV element        : <elm1>;
-- Trimmed CSV element: <elm1>;
-- CSV element        : < elm2>;
-- Trimmed CSV element: <elm2>;
-- CSV element        : <elm3 >;
-- Trimmed CSV element: <elm3>;
-- CSV element        : <elm4 >;
-- Trimmed CSV element: <elm4>;
-- CSV element        : < elm5>;
-- Trimmed CSV element: <elm5>;

Answer 4

可以使用可以在for循环中使用的函数（不regexp用于 ThinkJet）：

创建类型和函数

CREATE OR REPLACE TYPE t_my_list AS TABLE OF VARCHAR2(100);
CREATE OR REPLACE
       FUNCTION cto_table(p_sep in Varchar2, p_list IN VARCHAR2)
         RETURN t_my_list
       AS
         l_string VARCHAR2(32767) := p_list || p_sep;
         l_sep_index PLS_INTEGER;
         l_index PLS_INTEGER := 1;
         l_tab t_my_list     := t_my_list();
       BEGIN
         LOOP
           l_sep_index := INSTR(l_string, p_sep, l_index);
           EXIT
         WHEN l_sep_index = 0;
           l_tab.EXTEND;
           l_tab(l_tab.COUNT) := TRIM(SUBSTR(l_string,l_index,l_sep_index - l_index));
           l_index            := l_sep_index + 1;
         END LOOP;
         RETURN l_tab;
       END cto_table;
/

那么如何在for循环中调用它：

DECLARE
  parm1 varchar2(4000) := '123,234,345,456,567,789,890';
BEGIN
    FOR x IN (select * from (table(cto_table(',', parm1)) ) )
    LOOP
        dbms_output.put_line('callProdcedure2 called with ' || x.COLUMN_VALUE);
        callProdcedure2(x.COLUMN_VALUE);
    END LOOP;
END;
/

请注意 Oracle 给出的默认名称COLUMN_VALUE，这是我想要使用结果所必需的。

结果符合预期：

callProdcedure2 called with 123
callProdcedure2 called with 234
...