1

我一直在学习哈希和你可以用它们做的各种事情。今天我有这个问题。当我有 2 个键时，如何按值对哈希进行排序？以及如何打印出来？我有一个 csv 文件。我试图将值存储在哈希中，按值排序。这样我就可以打印最大和最小值，我还需要这个值在那里的日期。到目前为止，我可以打印哈希，但我无法对其进行排序。

#!/usr/bin/perl 
#find openMin and openMax. 
use warnings; 
use strict;

my %pick;
my $key1;
my $key2;
my $value;  
my  $file= 'msft2.csv';              
my $lines = 0;
my $date;
my $mm;
my $mOld = "";

my $open;
my $openMin;
my $openMax;
open (my $fh,'<', $file) or die "Couldnt open the $file:$!\n";
while  (my $line=<$fh>)
{ 
    my @columns = split(',',$line);
    $date = $columns[0];
    $open = $columns[1];

    $mm = substr ($date,5,2);

    if ($lines>=1) {                        #first line of file are names of columns     wich i 
    $key1 = $date;                         #dont need. data itself begins with second line 
    $key2 = "open";
    $value = $open;
    $pick{$key1}{"open"}=$value; 


   }
 $lines++;
} 
foreach $key1 (sort keys %pick) {
foreach $key2 (keys %{$pick{$key1}}) {
    $value = $pick{$key1}{$key2};
    print "$key1 $key2 $value \n";

 }
}
exit;
4

2 回答 2

3

1. 使用真正的 CSV 解析器

解析 CSV 可以split /,/正常工作...除非您的某个字段包含逗号。如果您绝对、肯定、100% 确定您的代码将永远不必在其中一个字段中解析带有逗号的 CSV，请随意忽略这一点。如果没有，我建议使用Text::CSV。示例用法：

use Text::CSV;

my $csv = Text::CSV->new( { binary => 1 } )
    or die "Cannot use CSV: " . Text::CSV->error_diag ();

open my $fh, "<", $file or die "Failed to open $file: $!";
while (my $line = $csv->getline($fh)) {
    print @$line, "\n";
}
$csv->eof or $csv->error_diag();
close $fh;

2. 排序

我在您的哈希中只看到一个辅助键：open. 如果您尝试根据 的值进行排序open，请执行以下操作：

my %hash = (
    foo => { open => "date1" },
    bar => { open => "date2" },
);

foreach my $key ( sort { $hash{$a}{open} cmp $hash{$b}{open} } keys %hash ) {
    print "$key $hash{$key}{open}\n";
}

（这假设您要排序的值不是数字。如果值是数字（例如3, -17.57），请使用 spaceship 运算符<=>而不是字符串比较运算符cmp。有关perldoc -f sort详细信息和示例，请参阅。）

编辑：你还没有解释你的日期是什么格式。如果它们是YYYY-MM-DD格式，上面的排序将起作用，但如果它们是MM-DD-YYYY格式，例如，01-01-2014将在12-01-2013. 解决此问题的最简单方法是将日期的组成部分从最重要到最不重要重新排序（即年，月，日）。您可以使用Time::Piece来执行此操作，如下所示：

use Time::Piece;

my $date = "09-26-2013";
my $t = Time::Piece->strptime($date, "%m-%d-%Y");
print $t->strftime("%Y-%m-%d");

另一个花絮：通常你应该只在使用变量之前声明它们。通过在程序顶部声明所有内容，除了降低可读性之外，您一无所获。

于 2013-09-26T20:43:04.017 回答
0

您可以将 key1 和 key2 连接成一个键，如下所示：

$key = "$key1 key2";
$pick{$key} = $value;
于 2013-09-26T20:03:48.423 回答