12

我有一个函数foo，它将指向内存的指针作为参数，并写入和读取该内存：

cdef void foo (double *data):
   data[some_index_int] = some_value_double
   do_something_dependent_on (data)

我分配data喜欢这样：

cdef int N = some_int
cdef double *data = <double*> malloc (N * sizeof (double))

cdef int i
for i in cython.parallel.prange (N, nogil=True):
    foo (data)

readout (data)

我现在的问题是：不同的线程如何处理这个？我的猜测是，指向的内存data将由所有线程共享，并在函数内部“同时”读取或写入foo。这会弄乱所有结果，因为不能依赖先前设置的数据值（在 内foo）？我的猜测是正确的还是在 cython 编译器中实现了一些神奇的安全带？

非常感谢您提前。

4

2 回答 2

9

一个好方法是让主数组位于线程之外。然后你给每个线程一个指针，指向应该由线程计算的主数组部分。

以下示例是矩阵乘法的实现（类似于dot二维数组），其中：

c = a*b

这里的并行性是在 的行上实现的a。检查指针是如何传递给multiply函数的，以允许不同的线程共享相同的数组。

import numpy as np
cimport numpy as np
import cython
from cython.parallel import prange

ctypedef np.double_t cDOUBLE
DOUBLE = np.float64


def mydot(np.ndarray[cDOUBLE, ndim=2] a, np.ndarray[cDOUBLE, ndim=2] b):
    cdef np.ndarray[cDOUBLE, ndim=2] c
    cdef int i, M, N, K

    c = np.zeros((a.shape[0], b.shape[1]), dtype=DOUBLE)
    M = a.shape[0]
    N = a.shape[1]
    K = b.shape[1]

    for i in prange(M, nogil=True):
        multiply(&a[i,0], &b[0,0], &c[i,0], N, K)

    return c


@cython.wraparound(False)
@cython.boundscheck(False)
@cython.nonecheck(False)
cdef void multiply(double *a, double *b, double *c, int N, int K) nogil:
    cdef int j, k
    for j in range(N):
        for k in range(K):
            c[k] += a[j]*b[k+j*K]

要检查你可以使用这个脚本：

import time

import numpy as np

import _stack

a = np.random.random((10000,500))
b = np.random.random((500,2000))

t = time.clock()
c = np.dot(a, b)
print('finished dot: {} s'.format(time.clock()-t))

t = time.clock()
c2 = _stack.mydot(a, b)
print('finished mydot: {} s'.format(time.clock()-t))

print 'Passed test:', np.allclose(c, c2)

在我的电脑上它给出的位置：

finished dot: 0.601547366526 s
finished mydot: 2.834147917 s
Passed test: True

如果 的行数a小于列数或列数b会mydot更差，需要更好地检查哪个维度来进行并行化。

于 2013-12-11T13:21:31.970 回答
2

我假设没有读取或写入data线程同步锁将读取/写入内存位置并覆盖彼此的更改。如果没有某种同步，您将无法获得一致的结果。

尽管文档（http://docs.cython.org/src/userguide/parallelism.html）似乎建议 OpenMP （默认后端）自动创建线程本地。

于 2013-12-10T14:07:32.763 回答