7

我编写了一个绑定 C++ 类，它从 C++ 调用 java。我正在尝试使用 CMake 编译绑定类（因为将使用绑定类的工具使用 CMake）。

但是我收到以下错误：

CMakeFiles/JNIWrapper.dir/JNIWrapper.cpp.o: In function `createVM(JavaVM_**)':
JNIWrapper.cpp:(.text+0x52): undefined reference to `JNI_CreateJavaVM'
collect2: ld returned 1 exit status
make[2]: *** [JNIWrapper] Error 1
make[1]: *** [CMakeFiles/JNIWrapper.dir/all] Error 2
make: *** [all] Error 2

这是我的 CMakeLists.txt：

cmake_minimum_required(VERSION 2.8.6)

project(AProject)

FIND_PACKAGE(JNI REQUIRED)

SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -I/usr/lib/jvm/java-6-openjdk-amd64/include -I/usr/lib/jvm/java-6-openjdk-amd64/include/linux -L/usr/lib/jvm/java-6-openjdk-amd64/jre/lib/amd64/server")

SET(CMAKE_EXE_LINKER_FLAGS "-ljvm")

# add the binary tree directory to the search path for include files
include_directories(${CMAKE_CURRENT_SOURCE_DIR})
include_directories(${JNI_INCLUDE_DIRS})

# add the executable
add_executable (JNIWrapper JNIWrapper.cpp)

任何建议表示赞赏。

PS：我尝试使用传统方式和编写makefile来编译它。我按照该示例编写了上面的 CMakeLists.txt 脚本。

4

1 回答 1

21

下面概述CMakeLists.txt了使用 CMake 构建示例 JNI 项目所需的步骤：

cmake_minimum_required (VERSION 3.0)

find_package(Java REQUIRED)
find_package(JNI REQUIRED)
include(UseJava)

enable_testing()
project (JNIFoo)

# compile JNIFoo.java to class file
set(CMAKE_JAVA_COMPILE_FLAGS "-source" "1.6" "-target" "1.6")
add_jar(JNIFoo JNIFoo.java)
get_target_property(_jarFile JNIFoo JAR_FILE)
get_target_property(_classDir JNIFoo CLASSDIR)

# generate JNIFoo.h stub
set (_stubDir "${CMAKE_CURRENT_BINARY_DIR}")
add_custom_command(
    OUTPUT JNIFoo.h
    COMMAND ${Java_JAVAH_EXECUTABLE} -verbose
        -classpath ${_classDir}
        -d ${_stubDir}
        -jni JNIFoo
    DEPENDS JNIFoo
    )

# generate libfoo.jnilib
include_directories(${JNI_INCLUDE_DIRS} ${_classDir} ${_stubDir})
add_library(foo MODULE foo.c JNIFoo.h)
set_target_properties(foo PROPERTIES SUFFIX ".jnilib")
target_link_libraries(foo ${JNI_LIBRARIES})

# add test to run JNIFoo
add_test(NAME TestJNIFoo
    COMMAND ${Java_JAVA_EXECUTABLE}
    -Djava.library.path=${CMAKE_CURRENT_BINARY_DIR}
    -cp ${_jarFile} JNIFoo)

该文件JNIFoo.java包含一个 Java 类，该类将一个函数声明foo.c为本地方法nativeFoo。foo.c包含该方法的 C 实现nativeFoo。

CMake 函数add_jar将 Java 类编译为 jar 文件，并作为副作用创建一个类文件，该类文件需要作为输入传递给javahC 存根文件生成器可执行文件。自定义命令用于调用javah以生成存根标头JNIFoo.h作为输出文件。

因为 Java 使用System.loadLibrary在运行时加载 JNI 库，所以必须MODULE使用 CMake 命令add_library将 JNI 库生成为库。添加JNIFoo.h为源文件可确保JNIFoo.h在编译库之前创建该文件。编译后的 JNI 库需要与变量中包含的 JDK JNI 库链接JNI_LIBRARIES。JNI_INCLUDE_DIRS包含要使用的 JNI 包含目录。

最后，添加了一个测试以使用 JVM 运行 JNIFoo 类。系统属性java.library.path必须设置为包含生成的 JNI 库的目录libfoo.jnilib。

于 2013-09-26T17:13:01.177 回答