1

受另一个答案中的设置链接的启发，我想绘制图表并显示不同的比例轴。

set grid mytics
set xrange[1:5]  
set yrange[0:3]
set y2range[0:30]
set xlabel "a"   
set ylabel "b"  
set ytics 
set y2label "c"
set mytics 2

ca = 0.05
cb = 0.5

f(x) = sin(x*pi/180)*cb *1000
i(x) = asin(x/1000 / cb )/pi*180
set link y2 via f(y) inverse i(y)

pl asin(ca /x)/pi*180 title "a"

它按预期绘制了图和轴，但我想要的是 y2 轴上的抽动在 ytics 上是精确的（尽管它们将是非整数）

4

2 回答 2

1

没有选项可以将例如6均匀分布的抽动放在一个轴上（就像用 来完成的那样set my2tics 7）。但是您可以手动添加抽动，因为您知道功能范围。

首先，您需要清除所有y2tics自动

set y2tics (f(0))

然后你可以在一个循环中设置所有次要和主要的抽动：

do for [i=0:6] {
    set y2tics add (f(i/2.0))
    set y2tics add ('' f(i/2.0 + 0.25) 1)
}

请注意，带有浮点增量的循环不起作用。

所以你的完整脚本如下所示：

reset
set grid mytics
set xrange[1:5]  
set yrange[0:3]
set y2range[0:30]
set xlabel "a"   
set ylabel "b"  
set ytics nomirror
set y2label "c"
set mytics 2

ca = 0.05
cb = 0.5

f(x) = sin(x*pi/180)*cb *1000
i(x) = asin(x/1000 / cb )/pi*180
set link y2 via f(y) inverse i(y)

set format y2 '%.2f'
set y2tics (f(0)) # clear all automatic y2tics
do for [i=0:6] {
    set y2tics add (f(i/2.0))
    set y2tics add ('' f(i/2.0 + 0.25) 1)
}

pl asin(ca /x)/pi*180 title "a"

结果：

在此处输入图像描述

只要知道主要抽动的数量，就有一种方法可以设置y2tics独立的。yrange首先您使用unknown终端绘图，之后您可以将yrange值作为变量GPVAL_Y_MIN和GPVAL_Y_MAX. 不幸的是，无法访问轴的抽动数：

...
set link y2 via f(y) inverse i(y)

set terminal push # save current terminal
set terminal unknown
pl asin(ca /x)/pi*180 title "a"

num_tics = 7
set format y2 '%.2f'
set y2tics (f(GPVAL_Y_MIN)) # clear all automatic y2tics
Y0 = GPVAL_Y_MIN
DY = (GPVAL_Y_MAX - GPVAL_Y_MIN)/(num_tics-1)
do for [i=0:(num_tics-1)] {
    set y2tics add (f(Y0+i*DY))
    set y2tics add ('' f(Y0+(i+0.5)*DY) 1)
}

set terminal pop # restore terminal
replot
于 2013-09-24T09:28:28.200 回答
0

似乎整数xtics 默认映射到 x2tics。

以下片段是从 https://stackoverflow.com/a/52121541/11769765修改的 在此处输入图像描述

set tics nomirror
set x2tics
set link x2 via x**2 inv sqrt(x)
plot sin(x)

但是，十进制值未映射，如放大时所见： 在此处输入图像描述

于 2020-02-24T09:44:37.883 回答