2

我有这个代码：

static def parseString(String inputRow, Particle particle) {
        def map = inputRow.split()
        particle.mass = map[0].toDouble()
        particle.x = map[1].toDouble()
        particle.y = map[2].toDouble()
}

而这个测试代码：

static final inputRow = "1 -5.2 3.8"
def particle1 = new Particle()

def "string should be parsed into particles"() {
    when:
    RepulsionForce.parseString(inputRow, particle1);

    then:
    particle1.mass == 1
    particle1.x == -5.2
    particle1.y == 3.8
}

上述测试按原样通过；但是，当我将 parseString 代码更改为以下代码时：

static def parseString(String inputRow, Particle particle) {
        def map = inputRow.split()
        particle.mass = map[0].toFloat()
        particle.x = map[1].toFloat()
        particle.y = map[2].toFloat()
}

相同的测试失败并出现此错误：

Condition not satisfied:

particle1.x == -5.2
|         | |
|         | false
|         -5.2
Particle@a548695
4

1 回答 1

5

默认情况下，-5.2在 Groovy 中是 BigDecimal，因此您将 Bi​​gDecimal 与 Float 对象进行比较。这些通过：

def a = -5.2
def b = "-5.2".toFloat()
assert a != b
assert a.getClass() == BigDecimal
assert b.getClass() == Float
assert a.toFloat() == b

Groovy 接受 BigDecimal 和 Double 之间的比较：

def g = -5.2
def h = "-5.2".toDouble()
assert g == h
assert g.getClass() == BigDecimal
assert h.getClass() == Double

如果您需要进行一些需要精度的计算，您可能会更好地使用 BigDecimal，因为它们会保留它（尽管会降低性能）

def c = -5.2
def d = "-5.2".toBigDecimal()
assert c == d
assert c.getClass() == BigDecimal
assert d.getClass() == BigDecimal

否则，根据@Tim 的评论，使用 a -5.2f，因此对 Float 对象进行比较：

def e = -5.2f
def f = "-5.2".toFloat()
assert e == f
assert e.getClass() == Float
assert f.getClass() == Float
于 2013-09-23T17:20:45.760 回答