0

我想制作一个程序，为函数创建解析树。例如：“f(g(x,h(y),v,k(l(c))))”可能是一个有效的函数调用。

h1.l

%{
#include <iostream>
#include <list>
using namespace std;
#include "h1.tab.hpp"

%}

%option noyywrap
%option c++

%%

[a-z][a-zA-z0-9]*       { yylval.s = yytext; return (TERM_ID); }
"("                     { return (OP); }
")"                     { return (CP); }
";"                     { return (COMMA); }

%%

h1.ypp

%{

#include <list>
#include <string>
#include <iostream>

using namespace std;


extern "C" int yylex(); 
extern "C" int yyerror(char *p) { cerr << "Error!" << endl; }

struct ts {
    string                  *name;
    list<struct ts*>        *plist; /* NULL if the sturcture represents a variable, parameter list if the structure represents a function */
};

%}

%union {
    struct ts *t;
    list<struct ts *> *tl;
    char *s;
}

%token <s> TERM_ID
%token OP CP COMMA

%type <tl> termlist
%type <t> term


%%

term : TERM_ID OP termlist CP   { $$ = new struct ts(); $$->name = new string($1); $$->plist = $3; }
    | TERM_ID   { $$ = new struct ts(); $$->name = new string($1); $$->plist = NULL; }
;

termlist : termlist COMMA term  { $$ = $1; $$->push_back($3); }
    | term  { $$ = new list<struct ts*>(); $$->push_back($1); }
;


%%

int main()
{
    yyparse();
    return 0;
}

编译：

$ bison -d h1.ypp
$ flex h1.l 
$ g++ h1.tab.cpp lex.yy.cc
h1.tab.cpp: In function ‘int yyparse()’:
h1.tab.cpp:1382: warning: deprecated conversion from string constant to ‘char*’
h1.tab.cpp:1528: warning: deprecated conversion from string constant to ‘char*’
Undefined symbols for architecture x86_64:
  "_yylex", referenced from:
      yyparse()    in ccmRHVKn.o
ld: symbol(s) not found for architecture x86_64
collect2: ld returned 1 exit status

我对这些工具了解不多，也从未使用过cpp。

我应该改变什么才能使这些东西起作用？

4

2 回答 2

1

您正在生成一个 C++ yylex，然后extern "C"在解析器中声明它。C++ 函数和 C 函数没有相同的名称（即使它们看起来是相同的），因此链接器无法找到yylex（或者_yylex，因为它实际上是被调用的。）

从两个声明中删除外部“C”，它可能会链接。

你应该改变char* s你的%unionto std::string* s; 否则，您将遇到初学者最常见的 bison/flex 问题之一：C 字符串yytext指向仅yylex在下一次调用之前有效，因此当 bison 开始使用指针时，它指向一个不同的字符串。

所以你需要yytext在词法分析器中制作副本，而不是在解析器中。因此，在您的词法分析器中，您将执行以下操作：

yylval.s = new std::string(yytext);

在你的语法中，你会做（例如）：

term : TERM_ID OP termlist CP   { 
         $$ = new struct ts();
         $$->name = $1;        // <-- Here is the change
         $$->plist = $3;
       }
于 2013-09-21T14:38:06.117 回答
1

问题是您正在生成一个 C++ 词法分析器类（%option c++在 .l 文件中使用），而 bison 需要一个 Cyylex函数。删除%option c++并改为添加extern "C" int yyex();到.l文件顶部（或extern "C"从.y文件中删除），一切都应该没问题。

于 2013-09-21T20:00:25.177 回答