1

我有一个 RDF 文件，我需要在一行中从中提取一些信息。

现在，我将 AllegroGraph 与 Prolog 查询引擎一起使用：

(select (?result)
      (q ?a !rdfs:label ?alabel)
      (q ?b !rdfs:label ?blabel)
      (lisp ?result (string+ ?alabel " AND " ?blabel)))

在一行中获取结果：

 "{a1} AND {b1}" 
 "{a1} AND {b2}" 
 "{a2} AND {b1}" 
 "{a2} AND {b2}"

现在，我需要用字符串“OR”将 ?result 的所有行组合成一行。所以我得到：

 "{a1} AND {b1} OR {a1} AND {b2} OR {a2} AND {b1} OR {a2} AND {b2}"

prolog中是否有任何功能可以做到这一点？

4

1 回答 1

2

事实上，你只有a*在左边和b*右边意味着你有一些其他的选择条件，而不仅仅是一个标签。给定这样的数据：

@prefix : <http://example.org/>.
@prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>.

:a1 a :ClassA ; rdfs:label "a1" .
:a2 a :ClassA ; rdfs:label "a2" .
:b1 a :ClassB ; rdfs:label "b1" .
:b2 a :ClassB ; rdfs:label "b2" .

您可以通过它们的类（和）选择?a和，然后也可以提取它们的标签，其模式如下：?b:ClassA:ClassB

?a a :ClassA ; rdfs:label ?alabel .
?b a :ClassB ; rdfs:label ?blabel .

然后你可以得到{alabel} AND {blabel}abind和 a concat：

bind( concat( "{", ?alabel, "} AND {", ?blabel, "}" ) as ?AandB )

使用这些，像这样的查询

prefix : <http://example.org/>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>

select ?AandB { 
 ?a a :ClassA ; rdfs:label ?alabel .
 ?b a :ClassB ; rdfs:label ?blabel .
 bind( concat( "{", ?alabel, "} AND {", ?blabel, "}" ) as ?AandB )
}

将为您提供您已经可以获得的结果：

-------------------
| AandB           |
===================
| "{a2} AND {b2}" |
| "{a2} AND {b1}" |
| "{a1} AND {b2}" |
| "{a1} AND {b1}" |
-------------------

现在的诀窍是使用group_concat和一个隐式组将所有这些组合成一个字符串，分隔符为" OR "：

prefix : <http://example.org/>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>

select ( group_concat( ?AandB ; separator=" OR ") as ?string ) where { 
 ?a a :ClassA ; rdfs:label ?alabel .
 ?b a :ClassB ; rdfs:label ?blabel .
 bind( concat( "{", ?alabel, "} AND {", ?blabel, "}" ) as ?AandB )
}

得到结果：

----------------------------------------------------------------------
| string                                                             |
======================================================================
| "{a2} AND {b2} OR {a2} AND {b1} OR {a1} AND {b2} OR {a1} AND {b1}" |
----------------------------------------------------------------------

如果你愿意，你甚至可以去掉bind，直接把concat表达式放到group_concat. 您可能会发现更容易阅读（少跳动）或更难阅读（大单行），但至少有选择是件好事：

prefix : <http://example.org/>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>

select ( group_concat( concat( "{",?alabel,"} AND {",?blabel,"}" ) ; separator=" OR ") as ?string ) where { 
 ?a a :ClassA ; rdfs:label ?alabel .
 ?b a :ClassB ; rdfs:label ?blabel .
}

StackOverflow 上还有其他一些group_concat浮动示例，它们也可能对您有用：

于 2013-09-27T13:51:20.477 回答