3

为了简洁起见，我正在尝试定义一个生成匿名函数的宏，该函数采用一个名为它的参数，而不是

(λ (it) body)
我可以写
(λλ body)

（换句话说，(λλ body)转换为(λ (it) body)）

(define-syntax-parameter it #f)
(define-syntax λλ
  (syntax-rules ()
    ((_ body)
     (λ (x) (syntax-parameterize ((it x)) body)))))
(λλ (< it 0)) ; For testing

我明白operators.rkt:13:28: ?: literal data is not allowed; no #%datum syntax transformer is bound in the transformer environment in: #f了(define-syntax-parameter if #f)，但据我所知，这与球拍文档中关于如何使用的示例完全相同define-syntax-parameter。我可以通过用一个函数替换来抑制错误#f（我使用了member，但不是出于任何真正的原因），但是在这样做之后，我得到了operators.rkt:17:38: x: identifier used out of context in: x. 我究竟做错了什么？

4

2 回答 2

4

您省略了示例syntax-id-rules中的部分。它是指定应该扩展为的部分。或者，您可以使用：itxmake-rename-transformer

#lang racket
(require racket/stxparam)

(define-syntax-parameter it #f)
(define-syntax λλ
  (syntax-rules ()
    ((_ body)
     (λ (x) (syntax-parameterize ([it (make-rename-transformer #'x)]) body)))))
((λλ (< it 0)) 5)
((λλ (< it 0)) -5)

=>

#f
#t
于 2013-09-19T17:42:00.567 回答
-1

语法参数不是实现您心目中的宏的唯一方法。一种更简单（IMO）的方法是只使用datum->syntax注入标识符it：

(define-syntax (λλ stx)
  (syntax-case stx ()
    ((_ body ...)
     (with-syntax ((it (datum->syntax stx 'it)))
       #'(λ (it) body ...)))))

要使用您的示例：

(define my-negative? (λλ (< it 0)))
(my-negative? -1)   ;; => #t
于 2013-09-19T17:02:56.380 回答