2

我刚刚开始学习 XSLT，并且无法忽略重复的元素。

我一直在通过 Stack Overflow 进行搜索，并且看到人们提出类似的问题。我尝试了一个小例子来查看我的文件哪里出错了，并且能够忽略重复的元素。然而，当我有不止一种类型的元素时，我的问题似乎出现了。

例如：

文件1.xml

<?xml-stylesheet type="text/xsl" href="merge2.xsl"?>

<Main>
    <Records>
        <Record>
            <Description>A</Description>
        </Record>
        <Record>
            <Description>A</Description>
        </Record>
        <Record>
            <Description>B</Description>
        </Record>
        <Record>
            <Description>C</Description>
        </Record>
    </Records>
</Main>

合并2.xsl

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/Transform">
<xsl:output method="html"/>
<xsl:template match="/">
    <table border="1">
        <tr>
            <th>Type</th>
            <th>Count</th>
        </tr>
        <xsl:for-each select="Main/Records/Record">
            <xsl:if test ="not(preceding-sibling::Record(Description/text() = current()/Description/text()])">
                <tr>
                    <td><xsl:value-of select="Description"/></td>
                    <td><xsl:value-of select="count(//Record[Description/text()=current()/Description/text()])"/></td>
                </tr>
            </xsl:if>
        </xsl:for-each>
    </table>
</xsl:template>
</xsl:stylesheet>

这很好用，给了我想要的结果。

Type    Count
 A        2
 B        1
 C        1

但是，如果我要添加另一个 Records 元素，它似乎会一个接一个地处理这两个元素，例如

<?xml-stylesheet type="text/xsl" href="merge2.xsl"?>

<Main>
    <Records>
        <Record>
            <Description>A</Description>
        </Record>
        <Record>
            <Description>A</Description>
        </Record>
        <Record>
            <Description>B</Description>
        </Record>
        <Record>
            <Description>C</Description>
        </Record>
    </Records>
    <Records>
        <Record>
            <Description>B</Description>
        </Record>
        <Record>
            <Description>A</Description>
        </Record>
        <Record>
            <Description>C</Description>
        </Record>
        <Record>
            <Description>C</Description>
        </Record>
    </Records>
</Main>

这将产生以下内容。

Type        Count
 A            3
 B            2
 C            3
 B            2
 A            3
 C            3

它似乎在处理记录的第一个实例，然后转到下一个。有什么办法可以删除两者之间的重复项吗？

我尝试更改 for-each 以遍历每个 Records 实例，并尝试为它创建一个单独的模板，但是我似乎仍然缺少一些东西，因为我没有设法让它工作。

非常感谢您的帮助。

4

2 回答 2

5

尝试用preceding-sibling你preceding的xsl:if statement.

tr你有正确的想法来制作你的测试，这样你每次遇到的Description值只发出一次。但是，preceding-sibling停止通过父级的直接子级进行检查；preceding继续检查文档的前面部分，这是您要避免跨Records.

Record(仅供参考，应该在哪里也有一个错字Record[。这是一个完整的运营转型，包括这些变化：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="html"/>
  <xsl:template match="/">
    <table border="1">
      <tr>
        <th>Type</th>
        <th>Count</th>
      </tr>
      <xsl:for-each select="Main/Records/Record">
        <xsl:if test ="not(preceding::Record[Description/text() = current()/Description/text()])">
          <tr>
            <td><xsl:value-of select="Description"/></td>
            <td><xsl:value-of select="count(//Record[Description/text()=current()/Description/text()])"/></td>
          </tr>
        </xsl:if>
      </xsl:for-each>
    </table>
  </xsl:template>
</xsl:stylesheet>
于 2013-09-19T15:36:58.280 回答
1

尽管@kjhughes 能够回答您的问题，但为了更有效的方法，您需要使用Muenchain Method。

为此，您将定义一个分组键

<xsl:key name="Record-by-Description" match="Record" use="Description"/>

然后使用该键对这些项目进行分组

<xsl:apply-templates select="Record[generate-id() = generate-id(key('Record-by-Description', Description)[1])]" mode="group"/>

然后用那个键只计算那些特定的项目

<xsl:value-of select="count(key('Record-by-Description', Description))"/>

这个过程效率更高，并且不需要每次都导航整个结构。

所以，总的来说，当你使用这个 XML

<Main>
  <Records>
    <Record>
      <Description>A</Description>
    </Record>
    <Record>
      <Description>A</Description>
    </Record>
    <Record>
      <Description>B</Description>
    </Record>
    <Record>
      <Description>C</Description>
    </Record>
  </Records>
  <Records>
    <Record>
      <Description>B</Description>
    </Record>
    <Record>
      <Description>A</Description>
    </Record>
    <Record>
      <Description>C</Description>
    </Record>
    <Record>
      <Description>C</Description>
    </Record>
  </Records>
</Main>

并将此 XSLT 应用于它

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >
  <xsl:output method="xml" indent="yes" />
  <xsl:key name="Record-by-Description" match="Record" use="Description"/>

  <xsl:template match="@* | node()">
    <xsl:apply-templates select="@* | node()"/>
  </xsl:template>

  <xsl:template match="Main">
    <table>
      <tr>
        <th>Type</th>
        <th>Count</th>
      </tr>
      <xsl:apply-templates select="Records"/>
    </table>
  </xsl:template>

  <xsl:template match="Records">
    <xsl:apply-templates select="Record[generate-id() = generate-id(key('Record-by-Description', Description)[1])]" mode="group"/>
  </xsl:template>

  <xsl:template match="Record" mode="group">
    <tr>
      <td>
        <xsl:value-of select="Description"/>
      </td>
      <td>
        <xsl:value-of select="count(key('Record-by-Description', Description))"/>
      </td>
    </tr>
  </xsl:template>

</xsl:stylesheet>

它产生这个输出

<table>
  <tr>
    <th>Type</th>
    <th>Count</th>
  </tr>
  <tr>
    <td>A</td>
    <td>3</td>
  </tr>
  <tr>
    <td>B</td>
    <td>2</td>
  </tr>
  <tr>
    <td>C</td>
    <td>3</td>
  </tr>
</table>
于 2013-09-19T16:13:51.253 回答