1

我想用 gnuplot 重现这个情节：

在此处输入图像描述

我的数据有这种格式：

数据
1：时间
2：价格
3：数量

我试过这个：

plot file using 1:2 with lines, '' using 1:3 axes x1y2 with impulses

这给出了一个正常的时间序列图表，y1价格和y2数量一样。
接下来，我尝试了：

plot file using 2:1 with lines, '' using 2:3 axes x1y2 with impulses

y1这给出了随时间和数量而变化的价格序列y2。但是，我需要保持价格y1和成交量x2。

也许是这样的： 

plot file using 1:2 with lines,' ' using 2:3 axes y1x2 with impulses

但是，这并没有给出我想要的。

4

1 回答 1

3

Gnuplot没有官方的方法来绘制这种水平箱线图。但是，您可以使用boxxyerrorbars(shorthand boxxy) 来实现此目的。

由于我没有您的实际示例的任何测试数据，因此我从高斯随机游走生成了一个数据文件。要生成数据，请运行以下python脚本：

from numpy import zeros, savetxt, random

N = 500
g = zeros(N)
for i in range(1, N):
    g[i] = g[i-1] + random.normal()

savetxt('randomwalk.dat', g, delimiter='\t', fmt='%.3f')

接下来，我对“位置数据”（在您的情况下是体积数据）进行分箱。对于这个可以使用smooth frequency。这将计算y相同值的值的总和x。所以首先我使用了一个合适的分箱函数，它在一定范围内返回相同的值（x+- binwidth/2）。输出数据保存在一个文件中，因为对于绘图我们必须交换x和y值：

binwidth = 2
hist(x) = floor(x+0.5)/binwidth

set output "| head -n -2 > randomwalk.hist"
set table
plot 'randomwalk.dat' using (hist($1)):(1) smooth frequency
unset table
unset output

通常应该可以使用set table "randomwalk.hist"，但是由于一个错误，需要这种解决方法来过滤掉表输出的最后一个条目，请参阅我对Why does the 'set table' option in Gnuplot re-write the first entry in的回答最后一行？.

现在实际的绘图部分是：

unset key
set x2tics
set xtics nomirror

set xlabel 'time step'
set ylabel 'position value'
set x2label 'frequency'

set style fill solid 1.0 border lt -1

set terminal pngcairo
set output 'randwomwalk.png'

plot 'randomwalk.hist' using ($2/2.0):($1*binwidth):($2/2.0):(binwidth/2.0) with boxxy lc rgb '#00cc00' axes x2y1,\
     'randomwalk.dat' with lines lc rgb 'black'

这给出了结果（4.6.3，当然取决于你的随机数据）：

在此处输入图像描述

因此，对于您的数据结构，以下脚本应该可以工作：

reset
binwidth = 2
hist(x) = floor(x+0.5)/binwidth
file = 'data.txt'
histfile = 'pricevolume.hist'

set table histfile
plot file using (hist($2)):($3) smooth unique
unset table

# get the number of records to skip the last one
stats histfile using 1 nooutput

unset key
set x2tics
set xtics nomirror

set xlabel 'time'
set ylabel 'price'
set x2label 'volume'

set style fill solid 1.0 border lt -1

plot histfile using ($2/2.0):($1*binwidth):($2/2.0):(binwidth/2.0) every ::::(STATS_records-2) with boxxy lc rgb '#00cc00' axes x2y1,\
     file with lines using 1:2 lc rgb 'black'

请注意，这次跳过最后一个table条目是通过使用stats命令计算所有条目来完成的，并跳过最后一个every（是的，STATS_records-2是正确的，因为点编号从 开始0）。此变体不需要任何外部工具。

我还使用smooth unique，它计算 的平均值，而不是总和（用 完成smooth frequency）。

于 2013-09-19T15:32:17.693 回答