18

我怎样才能Enum从它的价值中得到描述？

我可以使用以下方法从名称中获取描述：

Public Shared Function GetEnumDescription(ByVal EnumConstant As [Enum]) As String
    Dim fi As FieldInfo = EnumConstant.GetType().GetField(EnumConstant.ToString())
    Dim attr() As DescriptionAttribute = _ 
                  DirectCast(fi.GetCustomAttributes(GetType(DescriptionAttribute), _
                  False), DescriptionAttribute())

    If attr.Length > 0 Then
        Return attr(0).Description
    Else
        Return EnumConstant.ToString()
    End If
End Function

但我不知道如何将变量名传递给这个函数。我试过像

GetEnumDescription([Enum].GetName(GetType(myEnum), 2)))

但我尝试过的一切都是正确的。

4

2 回答 2

18

如果你有一个枚举类型的变量，它很简单

GetEnumDescription(myEnum)

最小的工作示例：

Enum TestEnum
    <Description("Description of Value1")>
    Value1
End Enum

Public Sub Main()
    Dim myEnum As TestEnum = TestEnum.Value1
    Console.WriteLine(GetEnumDescription(myEnum)) ' prints "Description of Value1"
    Console.ReadLine()
End Sub

如果你有一个Integer变量，你需要先将它转换为你的枚举类型（CType也可以）：

GetEnumDescription(DirectCast(myEnumValue, TestEnum))

工作示例：

Enum TestEnum
    <Description("Description of Value1")>
    Value1 = 1
End Enum

Public Sub Main()
    Console.WriteLine(GetEnumDescription(DirectCast(1, TestEnum)))
    Console.ReadLine()
End Sub

您混淆的根源似乎是一个误解：您的方法不将枚举的“名称”作为参数，而是将 anEnum作为参数。那是不同的东西，这也是您尝试使用GetName失败的原因。

于 2013-09-19T07:25:44.337 回答
5

这是获取枚举描述作为扩展的另一种解决方案。

Imports System.ComponentModel
Imports System.Runtime.CompilerServices

<Extension()> Public Function GetEnumDescription(ByVal EnumConstant As [Enum]) As String
    Dim attr() As DescriptionAttribute = DirectCast(EnumConstant.GetType().GetField(EnumConstant.ToString()).GetCustomAttributes(GetType(DescriptionAttribute), False), DescriptionAttribute())
    Return If(attr.Length > 0, attr(0).Description, EnumConstant.ToString)
End Function

以前帖子中的示例用法：

Enum Example
    <Description("Value1 description.")> Value1 = 1
    <Description("Value2 description.")> Value2 = 2
End Enum

Sub Main()
    Console.WriteLine(DirectCast(2, Example).GetEnumDescription())
    Console.ReadLine()
End Sub
于 2015-07-14T23:07:04.370 回答