11

我希望使用 groovy 将 xml 转换为 JSON。我了解转换的细节取决于我的偏好，但有人可以推荐我应该使用哪些库和方法，并为我提供一些关于为什么/如何使用它们的信息吗？我正在使用 groovy，因为有人告诉我它是一个非常有效的解析器，所以我正在寻找可以利用这一点的库

谢谢！

4

4 回答 4

10

您可以使用基本的 Groovy 完成所有操作：

// Given an XML string
def xml = '''<root>
            |    <node>Tim</node>
            |    <node>Tom</node>
            |</root>'''.stripMargin()

// Parse it
def parsed = new XmlParser().parseText( xml )

// Convert it to a Map containing a List of Maps
def jsonObject = [ root: parsed.node.collect {
  [ node: it.text() ]
} ]

// And dump it as Json
def json = new groovy.json.JsonBuilder( jsonObject )

// Check it's what we expected
assert json.toString() == '{"root":[{"node":"Tim"},{"node":"Tom"}]}'

但是，您确实需要考虑某些事情...

  • 你将如何表示属性？
  • 您的 XML 是否包含<node>text<another>woo</another>text</node>样式标记？如果是这样，您将如何处理？
  • 数据中心？注释？ETC？

这两者之间并不是一个平滑的 1:1 映射……但是对于给定的特定格式的 XML，可能会想出给定的特定格式的 Json。

更新：

要从文档中获取名称（请参阅评论），您可以执行以下操作：

def jsonObject = [ (parsed.name()): parsed.collect {
  [ (it.name()): it.text() ]
} ]

更新 2

您可以通过以下方式添加对更大深度的支持：

// Given an XML string
def xml = '''<root>
            |    <node>Tim</node>
            |    <node>Tom</node>
            |    <node>
            |      <anotherNode>another</anotherNode>
            |    </node>
            |</root>'''.stripMargin()

// Parse it
def parsed = new XmlParser().parseText( xml )

// Deal with each node:
def handle
handle = { node ->
  if( node instanceof String ) {
      node
  }
  else {
      [ (node.name()): node.collect( handle ) ]
  }
}
// Convert it to a Map containing a List of Maps
def jsonObject = [ (parsed.name()): parsed.collect { node ->
   [ (node.name()): node.collect( handle ) ]
} ]

// And dump it as Json
def json = new groovy.json.JsonBuilder( jsonObject )

// Check it's what we expected
assert json.toString() == '{"root":[{"node":["Tim"]},{"node":["Tom"]},{"node":[{"anotherNode":["another"]}]}]}'

同样，所有先前的警告仍然适用（但此时应该听到更响亮的声音）;-)

于 2013-09-16T14:21:29.980 回答
8

这可以完成工作： http: //www.json.org/java/

在撰写此答案时，该 jar 可在以下网址获得：http: //mvnrepository.com/artifact/org.json/json/20140107

下面显示用法。

进口：

import org.json.JSONObject
import org.json.XML

转换：

static String convert(final String input) {
  int textIndent = 2
  JSONObject xmlJSONObj = XML.toJSONObject(input)
  xmlJSONObj.toString(textIndent)
}

相关的 Spock 测试以显示我们需要注意的某些场景：

void "If tag and content are available, the content is put into a content attribute"() {
  given:
  String xml1 = '''
  <tag attr1="value">
    hello
  </tag>
  '''
  and:
  String xml2 = '''
  <tag attr1="value" content="hello"></tag>
  '''
  and:
  String xml3 = '''
  <tag attr1="value" content="hello" />
  '''
  and:
  String json = '''
  {"tag": {
      "content": "hello",
      "attr1": "value"
  }}
  '''

  expect:
  StringUtils.deleteWhitespace(convert(xml1)) == StringUtils.deleteWhitespace(json)
  StringUtils.deleteWhitespace(convert(xml2)) == StringUtils.deleteWhitespace(json)
  StringUtils.deleteWhitespace(convert(xml3)) == StringUtils.deleteWhitespace(json)
}

void "The content attribute would be merged with the content as an array"() {
  given:
  String xml = '''
  <tag content="same as putting into the content"
       attr1="value">
    hello
  </tag>
  '''
  and:
  String json = '''
  {"tag": {
      "content": [
          "same as putting into the content",
          "hello"
      ],
      "attr1": "value"
  }}
  '''

  expect:
  StringUtils.deleteWhitespace(convert(xml)) == StringUtils.deleteWhitespace(json)
}

void "If no additional attributes, the content attribute would be omitted, and it creates array in array instead"() {
  given:
  String xml = '''
  <tag content="same as putting into the content" >
    hello
  </tag>
  '''
  and:
  String notExpected = '''
  {"tag": {[
          "same as putting into the content",
          "hello"
          ]}
  }
  '''
  String json = '''
  {"tag": [[
          "same as putting into the content",
          "hello"
          ]]
  }
  '''

  expect:
  StringUtils.deleteWhitespace(convert(xml)) != StringUtils.deleteWhitespace(notExpected)
  StringUtils.deleteWhitespace(convert(xml)) == StringUtils.deleteWhitespace(json)
}

希望这可以帮助任何仍然需要解决此问题的人。

于 2014-10-06T12:34:51.610 回答
5

我参加聚会有点晚了，但以下代码会将任何 XML 转换为一致的 JSON 格式：

def toJsonBuilder(xml){
    def pojo = build(new XmlParser().parseText(xml))
    new groovy.json.JsonBuilder(pojo)
}
def build(node){
    if (node instanceof String){ 
        return // ignore strings...
    }
    def map = ['name': node.name()]
    if (!node.attributes().isEmpty()) {
        map.put('attributes', node.attributes().collectEntries{it})
    }
    if (!node.children().isEmpty() && !(node.children().get(0) instanceof String)) { 
        map.put('children', node.children().collect{build(it)}.findAll{it != null})
    } else if (node.text() != ''){
        map.put('value', node.text())
    }
    map
}
toJsonBuilder(xml1).toPrettyString()

转换 XML...

<root>
    <node>Tim</node>
    <node>Tom</node>
</root>

进入...

{
    "name": "root",
    "children": [
        {
            "name": "node",
            "value": "Tim"
        },
        {
            "name": "node",
            "value": "Tom"
        }
    ]
}

欢迎反馈/改进！

于 2014-07-09T07:12:11.217 回答
0

我利用 staxon 将复杂的 XML 转换为 JSON。这包括具有属性的元素。

下面有一个将xml转换为json的例子。

https://github.com/beckchr/staxon/wiki/Converting-XML-to-JSON

于 2014-03-05T16:15:13.923 回答