11

在 Delphi 2009 中，我发现每当我在应用程序中使用 TThread.CurrentThread 时，应用程序关闭时都会收到如下错误消息：

Exception EAccessViolation in module ntdll.dll at 0003DBBA.
Access violation at address 7799DBBA in module 'ntdll.dll'.  Write of
address 00000014.

除非它只是我的机器，否则您可以在几秒钟内复制它：创建一个新的 Delphi Forms 应用程序，向表单添加一个按钮，并为按钮的事件处理程序使用如下内容：

procedure TForm1.Button1Click(Sender: TObject);
begin
  TThread.CurrentThread;
end;

在我的 Vista 机器和 XP 机器上，我发现如果我不点击按钮一切都很好，但如果我点击按钮，当我关闭应用程序时会收到上述错误消息。

所以......我想知道这是否是一个错误，但同时我认为我很可能只是不了解关于你应该如何在 Delphi 中使用 TThreads 的一些非常基本的东西。恐怕我有点像德尔福新手。

像这样使用 TThread.CurrentThread 有什么明显的问题吗？

如果没有，并且你有 Delphi 2009，如果你实现我的简单示例项目，你会遇到同样的问题吗？

更新：正如弗朗索瓦在下面指出的，这实际上是 Delphi 2009 中的一个错误 - 你可以在这里投票。

更新：此错误已在 Delphi 2010 中修复。

4

4 回答 4

15

不幸的是，这似乎是一个与类单元中终结部分的调用顺序相关的错误：

DoneThreadSynchronization清除ThreadLock结构，然后
FreeExternalThreads想要销毁刚刚在调用时创建的 Thread 对象CurrentThread，
这需要 ThreadLock 在对 in 的调用中已经
EnterCriticalSection(ThreadLock)初始化TThread.RemoveQueuedEvents...

更新：QC 报告中
现在有一个解决方法补丁。

于 2008-10-09T18:07:34.633 回答
12

在 CodeGear 发布修复程序之前，您可以使用下面的补丁。将它保存到一个独立的单元中，并在程序中的任何地方使用它。我也会尝试将其添加到 QC 中。

此版本适用于 D2009（原始）、更新 1 和更新 2。

{ Fix Delphi 2009's invalid finalization order in Classes.pas.
  Written by Primoz Gabrijelcic, http://gp.17slon.com.
  No rights reserved - released to public domain.
}
unit FixD2009Classes;

interface

implementation

uses
  Windows,
  SysUtils,
  Classes;

type
  TCode = array [0..109] of byte;

{$WARN SYMBOL_PLATFORM OFF}

procedure PatchClasses;
{$IFDEF ConditionalExpressions}
{$IF RTLVersion = 20}
var
  i         : integer;
  oldProtect: cardinal;
  pCode     : ^TCode;
  tmp       : DWORD;
const
  COffsets_Call: array [1..12] of integer = (0, 15, 24, 34, 49, 59, 69, 79, 89, 94, 99, 109);
  COffset_UnRegisterModuleClasses = 106;
  COffset_DoneThreadSynchronization = 94;
  COffset_FreeExternalThreads = 99;
  CCallDelta = COffset_FreeExternalThreads - COffset_DoneThreadSynchronization;
{$IFEND}
{$ENDIF}
begin
{$IFDEF ConditionalExpressions}
{$IF RTLVersion = 20}
  pCode := pointer(cardinal(@TStreamReader.ReadToEnd) + COffset_UnRegisterModuleClasses);
  Win32Check(VirtualProtect(pCode, COffsets_Call[High(COffsets_Call)], PAGE_READWRITE, oldProtect));
  try
    for i := Low(COffsets_Call) to High(COffsets_Call) do
      if pCode^[COffsets_Call[i]] <> $E8 then
        raise Exception.Create('Unexpected version of Classes - cannot patch');
    tmp := PDword(@pCode^[COffset_DoneThreadSynchronization+1])^;
    PDword(@pCode^[COffset_DoneThreadSynchronization+1])^ :=
      PDword(@pCode^[COffset_FreeExternalThreads+1])^ + CCallDelta;
    PDword(@pCode^[COffset_FreeExternalThreads+1])^ := tmp - CCallDelta;
  finally VirtualProtect(pCode, COffsets_Call[High(COffsets_Call)], oldProtect, oldProtect); end;
{$IFEND}
{$ENDIF}
end;

initialization
  PatchClasses;
end.
于 2008-10-10T15:58:09.673 回答
5

Delphi 2009 Update 3 的补丁单元。

{ Fix Delphi 2009's invalid finalization order in Classes.pas.
  Written by Primoz Gabrijelcic, http://gp.17slon.com.
  No rights reserved - released to public domain.

  D2009 update 3 only.
}
unit FixD2009Classes;

interface

implementation

uses
  Windows,
  SysUtils,
  Classes;

type
  TCode = array [0..144] of byte;

{$WARN SYMBOL_PLATFORM OFF}

procedure PatchClasses;
{$IFDEF ConditionalExpressions}
{$IF RTLVersion = 20}
var
  i         : integer;
  oldProtect: cardinal;
  pCode     : ^TCode;
  tmp       : DWORD;
const
  COffsets_Call: array [1..12] of integer = (0, 15, 24, 42, 47, 58, 73, 91, 101, 111, 134, 139);
  COffset_UnRegisterModuleClasses = 107;
  COffset_DoneThreadSynchronization = 134;
  COffset_FreeExternalThreads = 139;
  CCallDelta = COffset_FreeExternalThreads - COffset_DoneThreadSynchronization;
{$IFEND}
{$ENDIF}
begin
{$IFDEF ConditionalExpressions}
{$IF RTLVersion = 20}
  pCode := pointer(cardinal(@TStreamReader.ReadToEnd) + COffset_UnRegisterModuleClasses);
  Win32Check(VirtualProtect(pCode, COffsets_Call[High(COffsets_Call)], PAGE_READWRITE, oldProtect));
  try
    for i := Low(COffsets_Call) to High(COffsets_Call) do
      if pCode^[COffsets_Call[i]] <> $E8 then
        raise Exception.Create('Unexpected version of Classes - cannot patch');
    tmp := PDword(@pCode^[COffset_DoneThreadSynchronization+1])^;
    PDword(@pCode^[COffset_DoneThreadSynchronization+1])^ :=
      PDword(@pCode^[COffset_FreeExternalThreads+1])^ + CCallDelta;
    PDword(@pCode^[COffset_FreeExternalThreads+1])^ := tmp - CCallDelta;
  finally VirtualProtect(pCode, COffsets_Call[High(COffsets_Call)], oldProtect, oldProtect); end;
{$IFEND}
{$ENDIF}
end;

initialization
  PatchClasses;
end.
于 2009-06-11T16:04:28.943 回答
0

我认为 CurrentThread 是在 2009 年（或 2007 年）添加的。我家有2006。但是你确定它是一个类属性吗？

于 2008-10-09T17:59:56.290 回答