7

起初我对clojure真的很陌生。所以，我试图用honeysql动态组合查询：

(:use [honeysql.core :as sql]
      [honeysql.helpers :refer :all])

(sql/format {:select [:*] :from [:test]
             :where [:or [:= :name "foo"]
                         [:= :name "bar"]]})

;; ["SELECT * FROM test WHERE (name = ? OR name = ?)" "foo" "bar"]

我有函数构建子句：

(defn build-clause [names]
  [:or (map #(vector := :name %) names)])

(sql/format {:select [:*]
             :from [:test]
             :where (build-clause ["foo" "bar"])})

;; ClassCastException clojure.lang.PersistentVector cannot be cast to clojure.lang.Named

我认为问题在于返回的构建子句函数

[:or ([:= :name "foo"] [:= :name "bar"])]

我想要这个：

[:or [:= :name "foo"] [:= :name :bar]]

请问我应该如何以正确的方式重写构建子句？什么样的列表展开？

4

2 回答 2

8

你是对的，map 函数是插入一个列表作为第二个元素，而不是按照你的意图插入。

试试这个：

(defn build-clause2 [names]
  (into [:or] (map #(vector := :name %) names)))

或者：

(defn build-clause2 [names]
  (apply conj [:or] (map #(vector := :name %) names)))

或者：

(defn build-clause2 [names]
  (reduce conj [:or] (map #(vector := :name %) names)))

所有这些都将达到相同的结果，因此在这种情况下更多的是品味问题。

另外，build-clause是命名空间中的多方法honeysql.helpers。当您honeysql.helpers :refer :all可以创建名称冲突时。

于 2013-09-15T21:43:47.440 回答
7

还有merge-wherewhich 可用于合并 where 字段。它也接受 null，因此可以像这样捆绑它：

(->
  (select :*)
  (from :test)
  (merge-where (if (> id 0) [:= :id id]))
  (merge-where (if-not (nil? src) [:= :src src]))
  sql/format)

我只是想我会指出这一点，因为我花了太长时间才弄清楚这一点。

于 2015-02-01T12:38:47.207 回答