algorithm - AS3 随机算法

Question

我需要一个建议。我想要一个函数返回从 1 到 100 的随机数，条件是不重复选择的数字。这就像国际象棋桌一样，里面会充满随机的东西，而不是一件事而不是另一件事……如果有人能提出建议，我会很高兴。谢谢。

Answer 1

创建一个Array100 个数字 (1..100)，然后按“随机”对数组进行“排序”。然后，您可以一次拉出一个数字，按照自己的方式遍历数组。

我没有测试下面的代码，但我有这些可用的片段，你可以拼凑起来达到预期的结果。

public static function randomNumber(min:Number, max:Number):Number{
    var rnd:Number = Math.floor((Math.random()*((max+1)-min))+min);
    return rnd;
}

public static function randomize(arr:Array):Array{
    var len:Number = arr.length;
    var rnd:Number;
    var tmp:Object;
    for(var i:Number=0;i<len;i++){
        rnd = randomNumber(0,(len-1));
        tmp = arr[i];
        arr[i] = arr[rnd];
        arr[rnd] = tmp;
    }
    return arr;
}

var setOfNumbers:Array = new Array();
for(var i:int=0;i<100;i++){
    setOfNumbers[i] = (i+1);
}
var shuffledSetOfNumbers:Array = randomize(setOfNumbers);

笔记：

• 对于纯粹主义者来说，这种“随机化”并不是“真正的”随机化（如果你正在为拉斯维加斯赌博机编写洗牌器，你会想要使用不同的东西——例如！）
• 我randomNumber和randomize上面的功能static就像我通常将它们包含在我需要它们的应用程序中一样，但您不必以这种方式使用它
• 我的原始库使用Numbervsint或uint用于某些变量以在使用时提供更多选项，但请随时清理

Answer 2

也这样……

package 
{
    import flash.display.Sprite;
    import flash.events.Event;

    /**
     * ...
     * @author Vadym Gordiienko
     */
    public class Main extends Sprite 
    {

        public function Main():void 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);
        }

        private function init(e:Event = null):void 
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);
            // entry point

            var startArray:Array = generateNumberArray(100);
            var randomArray:Array = randomArray(startArray);
            trace("startArray = " + startArray);
            trace("randomArray = " + randomArray);
        }
        /**
         * generate Array of numbers by length
         * @param   length
         * @return Array of numbers
         */
        public static function generateNumberArray(length:int):Array 
        {
            var numberArray:Array = [];
            for (var i:int = 0; i < length; i++) 
            {
                numberArray[i] = i+1;
            }

            return numberArray;
        }

        /**
         * generate randomly mixed array by input array
         * @param   inputArray - simple not mixed array
         * @return Array - mixed array
         */
        public static function randomArray(inputArray:Array):Array 
        {
            var randomArray:Array = [];
            var tempArray:Array = [];
            for (var i:int = 0; i < inputArray.length; i++) 
            {
                tempArray.push(inputArray[i]);
            }
            while (tempArray.length)
            {
                var randomNumber:int = Math.round(Math.random() * (tempArray.length - 1));// get random number of left array
                randomArray.push( tempArray[randomNumber] );
                tempArray.splice(randomNumber, 1); // remove randomed element from temporary aarray
            }
            tempArray = null;
            delete [tempArray];

            return randomArray;
        }

    }

}