1

我似乎无法在 PROC REPORT 中包含计算变量。当计算变量是标题列时它工作正常，但当它构成 ACROSS 组的一部分时，我无法让它工作。我只能直接引用这些列，这只会给我一个 ACROSS 组的结果，而不是两者。

data have1;
   input username $  betdate : datetime. stake winnings winner;
   dateOnly = datepart(betdate) ;
   format betdate DATETIME.;
   format dateOnly ddmmyy8.;
   datalines; 
    player1 12NOV2008:12:04:01 90 -90 0
    player1 04NOV2008:09:03:44 100 40 1
    player2 07NOV2008:14:03:33 120 -120 0
    player1 05NOV2008:09:00:00 50 15 1
    player1 05NOV2008:09:05:00 30 5 1
    player1 05NOV2008:09:00:05 20 10 1
    player2 09NOV2008:10:05:10 10 -10 0
    player2 09NOV2008:10:05:40 15 -15 0
    player2 09NOV2008:10:05:45 15 -15 0
    player2 09NOV2008:10:05:45 15 45 1
    player2 15NOV2008:15:05:33 35 -35 0
    player1 15NOV2008:15:05:33 35 15 1
    player1 15NOV2008:15:05:33 35 15 1
run;

PROC PRINT; RUN;

Proc rank data=have1 ties=mean out=ranksout1 groups=2;
     var    stake winner;
     ranks  stakeRank winnerRank;
run;

PROC REPORT DATA=ranksout1 NOWINDOWS out=report;
    COLUMN stakerank winnerrank, (N stake=stakemean discountedstake);
    DEFINE stakerank / GROUP '' ORDER=INTERNAL;
    DEFINE winnerrank / ACROSS '' ORDER=INTERNAL;
    DEFINE stake / analysis sum noprint;
    DEFINE stakemean / analysis sum;
    DEFINE discountedstake / computed format=8.2 'discountedstake';
    COMPUTE discountedstake;
        _C4_ = _C3_ -1;
    ENDCOMP;
RUN;

我不明白如何计算连接到跨组的变量。这仅计算列“ C4 ”的“discountedstake”值，对第 7 列再次执行此操作没有意义。

如何在每个组中包含该计算变量的值？

4

1 回答 1

1 
PROC REPORT DATA=ranksout1 NOWINDOWS out=report;
    COLUMN stakerank winnerrank, (N stake=stakemean discountedstake);
    DEFINE stakerank / GROUP '' ORDER=INTERNAL;
    DEFINE winnerrank / ACROSS '' ORDER=INTERNAL;
    DEFINE stake / analysis sum noprint;
    DEFINE stakemean / analysis sum;
    DEFINE discountedstake / computed format=8.2 'discountedstake';
    COMPUTE discountedstake;
    _C4_ = _C3_ -1;
    _C7_ = _C6_ -1;
    ENDCOMP;
RUN;

您只需要提及要计算的每一列。如果您有很多数组，您可能可以使用数组执行此操作，或者提前在数据步骤/视图中执行此操作。

于 2013-09-13T13:59:22.450 回答