7

I have a seq of maps such as the coll below. I want to arrange it in a tree. Each map has a key named :parent which is the :id of the parent. Any hints on how can I do it ? 

(def coll [{:id 1} 
          {:id 2 :parent 1} 
          {:id 3 :parent 1}
          {:id 4 :parent 2}
          {:id 5 :parent 4}
          {:id 6 :parent 5}
          {:id 7 :parent 5}
          {:id 8 :parent 5}
          {:id 9 :parent 7}])
4

2 回答 2

7

如果它像树一样走路...

(require '[clojure.zip :as z])

(defn create-zipper [s]
  (let [g (group-by :parent s)] 
    (z/zipper g #(map :id (g %)) nil (-> nil g first :id))))

(def t (create-zipper coll)) ; using the coll defined in the OP

(-> t z/root)
;=> 1

(-> t z/children)
;=> (2 3)

(-> t z/next z/children)
;=> (4)

#(g (% :id))请注意，您可以通过用作子节点和(first (g nil))根节点来保留原始节点的格式（而不仅仅是返回 id 编号） 。

如果需要，您可以使用后序遍历来构建树的另一个表示。

于 2013-09-13T17:33:11.197 回答
2

这是一个使用序列理解的小解决方案。希望它是可读的，但它绝对不会赢得任何性能奖，因为它会在每个递归级别重新过滤列表。我想可能有一个非常有效的基于 reduce 的解决方案，但我仍然掌握编写这些的窍门 - 希望其他人会发布一个:)。

注意 - 我已经为每个节点返回了整个地图，因为我不确定你希望你的树看起来像什么......

(defn make-tree
   ([coll] (let [root (first (remove :parent coll))]
               {:node root :children (make-tree root coll)}))
   ([root coll]
       (for [x coll :when (= (:parent x) (:id root))]
           {:node x :children (make-tree x coll)})))

(pprint (make-tree coll)) 

    {:node {:id 1},
     :children
       ({:node {:parent 1, :id 2},
         :children
           ({:node {:parent 2, :id 4},
             :children
               ({:node {:parent 4, :id 5},
                 :children
                   ({:node {:parent 5, :id 6}, :children ()} 
                    {:node {:parent 5, :id 7},
                     :children ({:node {:parent 7, :id 9}, :children ()})}
                    {:node {:parent 5, :id 8}, :children ()})})})}
    {:node {:parent 1, :id 3}, :children ()})}
于 2013-09-13T10:09:18.867 回答