1

早上好，我已经检查了很多关于这个主题的回复，但没有成功......非常抱歉......

我有一个带有“课程”元素（“降神会”）的元素“课程”（“降神会”）的 xml 文档：（我删除了不必要的细节）

....
<seances>
    <seance date="2014-09-10T00:00:01">
...details in a 'seance'
    </seance>
    <seance date="2013-09-10T00:00:01">
...
    </seance>
...other 'seance' elements
</seances>

我的 xslt 样式表生成一个 html 文档：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"   
    xmlns:date="http://exslt.org/dates-and-times" 
        extension-element-prefixes="date" 
    xmlns:gr="http://www.w3.org/2000/svg"  >

<xsl:output method="html" encoding="iso-8859-1" indent="yes"  />
<xsl:import href="date.xsl" />

记住当天的日期：

<xsl:variable name="ddj" as="xs:dateTime" select="date:date-time()"/>

当课程日期可以（日期不在未来）时，我只想显示一个元素课程：

我已经尝试了很多这样的条件，但它总是错误的：

<xsl:template match="seance">
    <xsl:variable name="dateseance" as="xs:dateTime" select="@date"/>
    <xsl:value-of select="$dateseance" /><xsl:value-of select="$ddj" />
    <xsl:choose>
       <xsl:when test="$ddj  &gt;=  $dateseance">
          <xsl:text>-OK-</xsl:text>
       </xsl:when>
       <xsl:otherwise>
          <xsl:text>-Not OK-</xsl:text>
       </xsl:otherwise>
    </xsl:choose>   
 </xsl:template>

日期似乎没问题，但它打印：

2014-09-10T00:00:012013-09-11T10:00:00.004+02:00-不好-（不会打印！）

其他行应该是“好的”：

2013-09-10T00:00:012013-09-11T10:00:00.004+02:00-不行- 2012-09-10T00:00:012013-09-11T10:00:00.004+02:00-不行- 2012-09-10T00:00:012013-09-11T10:00:00.004+02:00-不好- 2012-09-10T00:00:012013-09-11T10:00:00.004+02:00-不好- 2012-09-10T00:00:012013-09-11T10:00:00.004+02:00-不行-

我希望它可以被理解...

非常感谢您的帮助。

精度：我在 mozilla/firefox 中处理它

4

2 回答 2

2

下面是一个 XSLT 1.0 解决方案，它忽略时区并假设两个日期/时间值都在同一个时区：

T:\ftemp>type dates.xml
<seances>
    <seance date="2014-09-10T00:00:01">
...details in a 'seance'
    </seance>
    <seance date="2013-09-10T00:00:01">
...
    </seance>
...other 'seance' elements
</seances>

T:\ftemp>xslt dates.xml dates.xsl
2014-09-10T00:00:01 2013-09-11T14:30:13 -Not OK-
2013-09-10T00:00:01 2013-09-11T14:30:13 -OK-

T:\ftemp>type dates.xsl
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
          xmlns:date="http://exslt.org/dates-and-times"
                extension-element-prefixes="date"
                version="1.0"
                xmlns:gr="http://www.w3.org/2000/svg"  >

<xsl:output method="html" encoding="iso-8859-1" indent="yes"  />

<xsl:variable name="ddj" select="substring(date:date-time(),1,19)"/>

<xsl:template match="seances">
  <xsl:apply-templates select="seance"/>
</xsl:template>

<xsl:template match="seance">
    <xsl:variable name="dateseance" select="@date"/>
    <xsl:value-of select="$dateseance" />
    <xsl:text> </xsl:text>
    <xsl:value-of select="$ddj" />
    <xsl:text> </xsl:text>
    <xsl:choose>
       <xsl:when test="translate($ddj,':T-','')  >=
                       translate($dateseance,':T-','')">
          <xsl:text>-OK-</xsl:text>
       </xsl:when>
       <xsl:otherwise>
          <xsl:text>-Not OK-</xsl:text>
       </xsl:otherwise>
    </xsl:choose>
  <xsl:text>&#xa;</xsl:text>
 </xsl:template>

</xsl:stylesheet>
T:\ftemp>

这是有效的，因为它将日期/时间值转换为数字，在 XSLT 1.0 中，可以使用>和进行比较<。

于 2013-09-11T18:32:28.613 回答
0

使用 XSLT 2.0 中的内置工具获取日期和时间似乎没有问题：

T:\ftemp>type dates.xml
<seances>
    <seance date="2014-09-10T00:00:01">
...details in a 'seance'
    </seance>
    <seance date="2013-09-10T00:00:01">
...
    </seance>
...other 'seance' elements
</seances>

T:\ftemp>xslt2 dates.xml dates.xsl
2014-09-10T00:00:012013-09-11T13:34:59.992-04:00-Not OK-
2013-09-10T00:00:012013-09-11T13:34:59.992-04:00-OK-

T:\ftemp>type dates.xsl
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema"
       exclude-result-prefixes="xs"
version="2.0"
    xmlns:gr="http://www.w3.org/2000/svg"  >

<xsl:output method="html" encoding="iso-8859-1" indent="yes"  />

<xsl:variable name="ddj" as="xs:dateTime" select="current-dateTime()"/>

<xsl:template match="seances">
  <xsl:apply-templates select="seance"/>
</xsl:template>

<xsl:template match="seance">
    <xsl:variable name="dateseance" as="xs:dateTime" select="@date"/>
    <xsl:value-of select="$dateseance" /><xsl:value-of select="$ddj" />
    <xsl:choose>
       <xsl:when test="$ddj  &gt;=  $dateseance">
          <xsl:text>-OK-</xsl:text>
       </xsl:when>
       <xsl:otherwise>
          <xsl:text>-Not OK-</xsl:text>
       </xsl:otherwise>
    </xsl:choose>
  <xsl:text>&#xa;</xsl:text>
 </xsl:template>

</xsl:stylesheet>
T:\ftemp>

你觉得有必要使用 exslt 有什么原因吗？

于 2013-09-11T17:36:50.090 回答