3

长话短说，我花了很长时间试图弄清楚如何使用调用和/或委托在使用线程时从单独的类更新用户表单。我很确定这对于有更多经验的人来说是愚蠢而明显的。我知道可能需要委托，但我所有的努力似乎只有在从主线程调用时才有效。我已经在互联网上看了半天，只是有些东西我没有得到。

下面以一些伪代码为例：

此选项有效：

Public Class Form1
Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
    Dim t1 As New Threading.Thread(AddressOf Count)

    t1.IsBackground = True

    t1.Start(100)
End Sub
Private Sub Count(ByVal Max As Object)
    If TypeOf Max Is Integer Then
        Count(CInt(Max))
    End If
End Sub


Private Sub SetLabelText(ByVal text As String)
    If Label1.InvokeRequired Then
        Label1.Invoke(New Action(Of String)(AddressOf SetLabelText), text)
    Else
        Label1.Text = text

    End If
End Sub

Private Sub Count(ByVal Max As Integer)
    For i = 1 To Max
        SetLabelText(CStr(i))
        Threading.Thread.Sleep(200)
    Next
End Sub
End Class

虽然这（我的 1000 次略有不同的变化之一）没有。实际上，对于这个示例，我只是尝试将其中一个潜艇分离到它自己的类中，但在其他方面与我可以做到的相同：

Public Class Form1
Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click

    Dim t1 As New Threading.Thread(AddressOf Count)
    t1.Start(100)

End Sub
Private Sub Count(ByVal Max As Object)
    If TypeOf Max Is Integer Then
        Dim class2 As New class2
        class2.Count(CInt(Max))
    End If
End Sub

Private Delegate Sub SetTextBoxTextInvoker(text As String)
Sub SetLabelText(ByVal text As String)
'or me.label1, form1.label1 or anything else I can try!
    If Me.InvokeRequired Then
        Me.Invoke(New SetTextBoxTextInvoker(AddressOf SetLabelText), _
               text)
    Else
        Me.Label1.Text = text
    End If
End Sub
End Class

Public Class class2
Sub Count(ByVal Max As Integer)
    For i = 1 To Max
        form1.SetLabelText(CStr(i))
        Threading.Thread.Sleep(200)
    Next
End Sub
End Class

据我所知，子“SetLabelText”中的invokerequired 的if 语句似乎永远不会被触发。我最好的猜测是我在检查 invokerequired 参数时没有正确引用用户表单？或者我需要向代表提供其他东西？我只是对弄乱我可能弄错的数百万个小变量感到沮丧。提前感谢您提供的任何帮助，如果您需要更多信息，请告诉我。

4

2 回答 2

2

我不确定我是否理解您要执行的操作，但是基于您的代码，您可以使用以下代码安全地设置标签（“线程安全”）：

Public Class Form1
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Dim t1 As New Threading.Thread(AddressOf Count)

        t1.IsBackground = True

        t1.Start(100)
    End Sub

    Private Sub Count(ByVal Max As Object)
        If TypeOf Max Is Integer Then
            Dim class2 As New Class2

            class2.Count(CInt(Max), AddressOf SetLabelText)
        End If
    End Sub

    Private Sub SetLabelText(ByVal text As String)
        If Label1.InvokeRequired Then
            Label1.Invoke(New SetText(AddressOf SetLabelText), text)
        Else
            Label1.Text = text
        End If
    End Sub
End Class

Public Class Class2
    Sub Count(ByVal Max As Integer, SetTextMethod As SetText)
        For i = 1 To Max
            SetTextMethod.Invoke((CStr(i)))

            Threading.Thread.Sleep(200)
        Next
    End Sub
End Class

Public Delegate Sub SetText(text As String)

我创建了一个名为“SetText”的代表；当表单在您的类中调用 count 函数时，您可以传递引用 SetLabelText 方法的委托实例。在该方法中，您可以直接或间接通过 Invoke 以及委托的新实例安全地设置标签文本。

您绝对不想做的事情是从您的课程中引用您的表单（即“form1.SetLabelText(CStr(i))”）；随着项目规模的扩大和需求的变化，这可能会造成真正的噩梦！

如果我误解了您的问题或没有正确回答，请回复。

于 2013-09-10T23:23:14.780 回答
2

首先，我建议使用任务并行库而不是线程。它更容易理解和使用。例如，

Dim countTask as New Task(Sub() Count(10))

Dim displayTask = countTask.ContinueWith(Sub()
                                           Me.Invoke(Sub() Label.Text = "10"

                                         End Sub)

 countTask.Start()

此示例假定您从表单本身调用它。您可以使用此方法将值从第一个任务返回到第二个任务。如果您需要更详细的示例并想要更多示例，请查看http://msdn.microsoft.com/en-us/library/hh228603.aspx。如果您需要进一步的帮助，我总是可以在 GitHub 或博客上发布一些关于它的内容。祝你好运。

于 2013-09-10T23:51:01.943 回答