1

编辑：我开始在这个问题上悬赏。目前，我已经开始使用 VS2010 Pro Beta 开发我的应用程序，但我真的希望它能够使用 express 版本构建，因为我们通常不是 .net 商店，即使一个或两个开发人员拥有 VS PRO，我们整个团队都无法使用它。

要成为公认的答案并获得赏金，您必须提供允许使用 vb 2008 express edition 安装和卸载 Windows 服务的示例代码和说明。您不一定需要从我的代码开始（但它的要点包括在下面）。

我编写了一个我想作为服务运行的 VB.NET 应用程序。目前我使用的是 VB.net Express Edition (2008)，它不附带“服务”模板，但我添加了一个服务类（从 ServiceBase 继承）和一个安装程序类（从安装程序继承）；在这两种情况下，我都遵循 MSDN 中的示例代码。不幸的是，我无法让此代码作为服务安装和运行。

这段代码的核心是一个名为 sampleListener 的 TCP 侦听器类。如果我将 sampleListener 类设置为启动对象并运行我的项目，它作为控制台应用程序运行良好。

有一个服务类（如下），它只是启动 sampleListener。 

Public Class sampleSocketService
    Inherits System.ServiceProcess.ServiceBase

    Public Sub New()
        Me.ServiceName = "sample Socket Service"
        Me.CanStop = True
        Me.CanPauseAndContinue = True
        Me.AutoLog = True
    End Sub

    Shared Sub Main()
        System.ServiceProcess.ServiceBase.Run(New sampleSocketService)
    End Sub

    Protected Overrides Sub OnStart(ByVal args() As String)
        sampleListener.Main()
    End Sub

End Class

还有一个安装程序类，我认为这是我的问题的根源。这是我最初编写的安装程序类。 

Imports System
Imports System.Collections
Imports System.Configuration.Install
Imports System.ServiceProcess
Imports System.ComponentModel

<RunInstallerAttribute(True)> _
Public Class sampleSocketServiceInstaller
    Inherits Installer
    Private serviceInstaller1 As ServiceInstaller
    Private processInstaller As ServiceProcessInstaller

    Public Sub New()
        ' Instantiate installers for process and services.
        processInstaller = New ServiceProcessInstaller()
        serviceInstaller1 = New ServiceInstaller()

        processInstaller.Account = ServiceAccount.LocalSystem
        serviceInstaller1.StartType = ServiceStartMode.Automatic

        ' ServiceName must equal those on ServiceBase derived classes.            
        serviceInstaller1.ServiceName = "sample Socket Service"

        ' Add installers to collection. Order is not important.
        Installers.Add(serviceInstaller1)
        Installers.Add(processInstaller)
    End Sub
End Class

在此运行 installutil.exe 会产生以下消息：

An exception occurred during the Install phase.
System.Security.SecurityException: The source was not found, but some or all event logs could not be searched.  Inaccessible logs: Security.

这看起来像是一个安全问题，但我正在使用以管理员身份运行打开的 cmd 窗口中运行。

我根据在线示例尝试了一个非常简化的安装程序类：

Imports System.ComponentModel
Imports System.Configuration.Install

<RunInstaller(True)> Public Class ProjectInstaller
    Inherits System.Configuration.Install.Installer

End Class

这看起来简单得可笑，我不知道它是如何工作的，事实上它没有。但是，在使用此版本的安装程序类的项目上运行 installutil.exe 时，installutil.exe 不会抛出错误消息并报告服务已成功安装。

我怀疑我的安装程序类中需要代码来执行我的第一个示例中的一些操作，但不执行导致错误的任何部分。

有什么建议么？

（为了清楚起见，已经对它进行了广泛的编辑，并添加了最初未包含的代码示例）

4

3 回答 3

6

这似乎对我有用，但我没有在你自己的代码中添加。

创建两个文件Service1.vb 和ProjectInstaller.vb。通常将 Service1 和 ProjectInstaller 设置为 Partial 类，但为了在此处发布，它们不是。我不认为它有任何副作用，但其他人可以对此发表评论。

我通常使用 bat 文件处理安装/卸载。

添加两个对项目的引用

System.ServiceProcess
System.Configuration.Install

服务1.vb

Imports System.ServiceProcess

Public Class Service1
Inherits System.ServiceProcess.ServiceBase

Protected Overrides Sub OnStart(ByVal args() As String)
End Sub

Protected Overrides Sub OnStop()
End Sub

<System.Diagnostics.DebuggerNonUserCode()> _
Protected Overrides Sub Dispose(ByVal disposing As Boolean)
    Try
        If disposing AndAlso components IsNot Nothing Then
            components.Dispose()
        End If
    Finally
        MyBase.Dispose(disposing)
    End Try
End Sub

<MTAThread()> _
<System.Diagnostics.DebuggerNonUserCode()> _
Shared Sub Main()
    Dim ServicesToRun() As System.ServiceProcess.ServiceBase

    ServicesToRun = New System.ServiceProcess.ServiceBase() {New Service1}

    System.ServiceProcess.ServiceBase.Run(ServicesToRun)
End Sub

Private components As System.ComponentModel.IContainer

<System.Diagnostics.DebuggerStepThrough()> _
Private Sub InitializeComponent()
    components = New System.ComponentModel.Container()
    Me.ServiceName = "Service1"
End Sub

End Class

项目安装程序.vb

Imports System.ComponentModel
Imports System.Configuration.Install

<System.ComponentModel.RunInstaller(True)> _
Public Class ProjectInstaller
Inherits System.Configuration.Install.Installer

Public Sub New()
    MyBase.New()

    InitializeComponent()

End Sub

<System.Diagnostics.DebuggerNonUserCode()> _
Protected Overrides Sub Dispose(ByVal disposing As Boolean)
    Try
        If disposing AndAlso components IsNot Nothing Then
            components.Dispose()
        End If
    Finally
        MyBase.Dispose(disposing)
    End Try
End Sub

Private components As System.ComponentModel.IContainer

<System.Diagnostics.DebuggerStepThrough()> _
Private Sub InitializeComponent()
    Me.ServiceProcessInstaller1 = New System.ServiceProcess.ServiceProcessInstaller
    Me.ServiceInstaller1 = New System.ServiceProcess.ServiceInstaller

    Me.ServiceProcessInstaller1.Account = System.ServiceProcess.ServiceAccount.LocalSystem
    Me.ServiceProcessInstaller1.Password = Nothing
    Me.ServiceProcessInstaller1.Username = Nothing

    Me.ServiceInstaller1.ServiceName = "Service1"
    Me.ServiceInstaller1.StartType = System.ServiceProcess.ServiceStartMode.Automatic

    Me.Installers.AddRange(New System.Configuration.Install.Installer() {Me.ServiceProcessInstaller1, Me.ServiceInstaller1})

End Sub
Friend WithEvents ServiceProcessInstaller1 As System.ServiceProcess.ServiceProcessInstaller
Friend WithEvents ServiceInstaller1 As System.ServiceProcess.ServiceInstaller

End Class

安装蝙蝠

C:
CD \WINDOWS\Microsoft.NET\Framework\v2.0.50727
installutil "C:\Visual Studio 2008\Projects\....\Temp.exe"
pause
NET START Service1

卸载蝙蝠

C:
CD \WINDOWS\Microsoft.NET\Framework\v2.0.50727
NET STOP Service1
installutil /u "C:\Visual Studio 2008\Projects\....\Temp.exe"

希望这对你有用

于 2009-12-22T11:17:22.220 回答
0

你可以做到，但我对你的解释有点困惑。您是否安装了该服务，或者您是否尝试将该服务作为控制台应用程序运行？您需要安装该服务，以便注册并从服务管理器运行它。或者您可以构建一个“主”方法，在您的 onstart 方法中运行代码，但您不能通过将服务类设置为启动方法来在调试模式下调用 onstart/onstop/pause 等方法。

您可以发布您的服务类（或至少发布足够的服务类以便我们可以看到您的代码）吗？

于 2009-12-08T22:53:03.877 回答
0

看看这个线程：

http://social.msdn.microsoft.com/Forums/en/windowsgeneraldevelopmentissues/thread/416098a4-4183-4711-a53b-e10966c9801d

于 2009-12-08T22:31:07.887 回答