batch-file - 批处理文件以编辑目录中的多个文件

Question

我想编辑以 .xml 扩展名结尾的目录中的文件。我编写了代码来编辑一个文件：

@echo off
echo Removing...
for /f "skip=17 delims=*" %%a in (C:\xml\file1.xml) do (
echo %%a >>C:\newfile.xml
) >nul
echo Lines removed, rebuilding file...
xcopy C:\newfile.xml C:\file.xml /y >nul
echo File rebuilt, removing temporary files
del C:\newfile.xml /f /q >nul
msg * Done!
exit >nul

我想编辑目录中的所有文件。

Answer 1

只是按照你的要求做：

@echo off
for %%F in ("C:\xml\*.xml") do (
  echo Processing %%F
  echo Removing...
  for /f "skip=17 delims=*" %%a in ("%%F") do (
    echo %%a >>C:\newfile.xml
  ) >nul
  echo Lines removed, rebuilding file...
  xcopy C:\newfile.xml "%%F" /y >nul
  echo File rebuilt, removing temporary files
  del C:\newfile.xml /f /q >nul
  msg * Done!
  echo(
)
exit >nul

但我相信你想要"delims="（没有分隔符）或"tokens=*"（所有标记），而不是"delims=*"（在 * 处中断）。

此外，代码可以大大简化并提高效率：

@echo off
for %%F in ("C:\xml\*.xml") do (
  >"%%F.new" (for /f "skip=17 delims=" %%a in ("%%F") do echo %%a)
  move /y "%%F.new" "%%F" >nul
  echo %%F
)
msg * Done!
exit /b

更快，只要您不需要保留 TAB 字符，并且文件不是太大，就使用 MORE（在某些时候，重定向的 MORE 在处理大文件时会挂起等待按键）。

@echo off
for %%F in ("C:\xml\*.xml") do (
  more +17 "%%F" >"%%F.new"
  move /y "%%F.new" "%%F" >nul
  echo %%F
)
msg * Done!
exit /b