0

A.xsl 导入 B.xsl，其中包含 A.xsl 中使用的函数。A.xsl 包含标识模板。B.xsl的函数需要对一个变量应用模板规则；但是，A.xsl 中的标识模板覆盖了它们。

我的想法是指向xsl:apply-importsB 中的变量，但与xsl:apply-templates没有办法将select=其指向变量不同。原始功能不能用模板规则代替。有没有办法在没有xsl:include-ing B.xsl 的情况下做到这一点？

A.xsl：

<xsl:stylesheet 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:my="http://me"
    version="2.0">

    <xsl:import href="B.xsl"/>

    <xsl:template match="X">
        <xsl:sequence select="my:do-stuff(.)"/>
    </xsl:template>

    <xsl:template match="@*|node()" mode="#all" priority="-1">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" mode="#current"/>
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

B.xsl：

<xsl:stylesheet 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:my="http://me"
    version="2.0">

    <xsl:template match="X" mode="cleanup">
        <clean><xsl:apply-templates/></clean>
    </xsl:template>

    <xsl:function name="my:do-other-stuff">
        <xsl:param name="x" as="element(X)"/>
        ...
    </xsl:function>

    <xsl:function name="my:do-stuff">
        <xsl:param name="x" as="element(X)"/>            
        <xsl:variable name="x-updated" select="my:do-other-stuff($x)"/>
        <xsl:apply-templates select="$x-updated" mode="cleanup"/>
    </xsl:function>

</xsl:stylesheet>
4

1 回答 1

0

mode="#all"一种选择是通过更改列出所有模式来防止标识模板被覆盖，除了 cleanup：

<xsl:template match="@*|node()" mode="#default not-cleanup1 not-cleanup2" priority="-1">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()" mode="#current"/>
    </xsl:copy>
</xsl:template>
于 2013-09-05T19:17:18.573 回答