0

拜托我需要你的帮忙，

XML：我有这个 SOAP 消息：

<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/">
<soapenv:Header/>
<soapenv:Body>
 <Service>
  <ServiceRequest>
   <tag3>value3</tag3>
  </ServiceRequest>
 </Service>
</soapenv:Body>
</soapenv:Envelope>

XSL：我需要从 xml 属性中添加节点。我尝试使用这个 xsl：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns="http://www.w3.org/1999/xhtml">
<xsl:output encoding="UTF-8" indent="yes" method="xml" standalone="no" omit-xml-declaration="no"/>
<xsl:variable name="props">
<properties>
 <property>
  <key>tag1</key>
  <value>value1</value>
 </property>
 <property>
  <key>tag2</key>
  <value>value2</value>
 </property>
</properties>
</xsl:variable>

<xsl:template match="@* | node()">
<xsl:copy>
 <xsl:apply-templates select="@* | node()" />
</xsl:copy>
</xsl:template>

<xsl:template match="ServiceRequest">
<xsl:copy>
 <xsl:apply-templates select="@* | node()" />
  <xsl:for-each select="$props/properties/property">
   <xsl:variable name="tag" select="key" />
   <xsl:element name="{$tag}">
    <xsl:value-of select="value" />
   </xsl:element>
  </xsl:for-each>
 </xsl:copy>
</xsl:template>
</xsl:stylesheet>

XSL 之后的 XML：我需要这样的结果：

<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/">
<soapenv:Header/>
<soapenv:Body>
 <Service>
  <ServiceRequest>
   <tag1>value1</tag1>
   <tag2>value2</tag2>
   <tag3>value3</tag3>
  </ServiceRequest>
 </Service>
</soapenv:Body>
</soapenv:Envelope>

但是 XSL 不起作用。你能帮我吗？

4

1 回答 1

0

问题是 XSLT 有一个默认命名空间xmlns="http://www.w3.org/1999/xhtml，因此propertiesandproperty元素在该命名空间中，因此select="$props/properties/property"不匹配任何内容，因为它们正在寻找 null 命名空间中的元素。

默认命名空间似乎不是必需的，所以最简单的解决方法就是删除它。

另一个可能的问题是该$prop变量包含一个 XML 片段而不是一个节点集——这意味着它需要在使用之前转换为一个节点集for-each——这是通过依赖于实现的 XSLT 扩展函数来完成的。

使用 Microsoft XSLT 处理器，正确的 XSLT 如下所示：

 <xsl:stylesheet 
  version="1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
  xmlns:msxsl="urn:schemas-microsoft-com:xslt" 
  exclude-result-prefixes="msxsl">

  <xsl:output encoding="UTF-8" indent="yes" method="xml" standalone="no" omit-xml-declaration="no"/>
  <xsl:variable name="props">
    <properties>
      <property>
        <key>tag1</key>
        <value>value1</value>
      </property>
      <property>
        <key>tag2</key>
        <value>value2</value>
      </property>
    </properties>
  </xsl:variable>

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()" />
    </xsl:copy>
  </xsl:template>

  <xsl:template match="ServiceRequest">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()" />
      <xsl:for-each select="msxsl:node-set($props)/properties/property">
        <xsl:variable name="tag" select="key" />
        <xsl:element name="{$tag}">
          <xsl:value-of select="value" />
        </xsl:element>
      </xsl:for-each>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>
于 2013-09-05T15:09:53.610 回答