-1

我在这里阅读了 3 年前发布的内容 ->如何从 Perl 阅读 Gmail 帐户中的邮件？

但我无法打开正文.. 我读过 Net::IMAP::Simple 和 Email::Simple; . 我正在尝试这个..但不起作用，它打印 de from 和主题，但不是身体。

use strict;
use warnings;

# required modules
use Net::IMAP::Simple;
use Email::Simple;
use IO::Socket::SSL;

# fill in your details here
my $username = 'email@gmail.com';
my $password = 'pass';
my $mailhost = 'imap.gmail.com';

# Connect
my $imap = Net::IMAP::Simple->new(
    $mailhost,
    port    => 993,
    use_ssl => 1,
) || die "Unable to connect to IMAP: $Net::IMAP::Simple::errstr\n";

# Log in
if ( !$imap->login( $username, $password ) ) {
    print STDERR "Login failed: " . $imap->errstr . "\n";
    exit(64);
}
# Look in the INBOX
my $nm = $imap->select('INBOX');

# How many messages are there?
my ($unseen, $recent, $num_messages) = $imap->status();
print "unseen: $unseen, recent: $recent, total: $num_messages\n\n";


## Iterate through unseen messages
for ( my $i = 1 ; $i <= $nm ; $i++ ) {
    if ( $imap->seen($i) ) {
        next;
    }
    else {
    my $es = Email::Simple->new( join '', @{ $imap->top($i) } );
    my $text = $es->body;
    printf( "[%03d] %s\n\t%s\n%s", $i, $es->header('From'), $es->header('Subject'),$text);
    }
}


# Disconnect
$imap->quit;

exit;

这个打印：

[001] <example@example.com>
     test subject

不是电子邮件的正文。

谁能解决这个？？？

提前致谢。

4

1 回答 1

1

问题是您正在使用：

$imap->top($i)

从文档（强调我的）：

此方法接受消息编号作为其必需参数。该消息将从当前选定的文件夹中检索。成功时，此方法返回一个包含标题行的列表引用。失败时不返回任何内容，并且使用错误消息设置 errstr() 错误处理程序。

top不返回邮件正文。你需要使用get它。像这样的东西：

my $es = Email::Simple->new( join '', @{ $imap->get($i) } );
                                                ^^^
于 2013-09-04T13:06:01.330 回答