0

我发现很难理解数组对象。在这种情况下，我不知道为什么 'wal[i].walk();' 被视为空指针异常。

walker[] wal;
int num= 70;
void setup() {
  size(800, 600);
  wal = new walker[num];
  background(255);
}

void draw() {

  for (int i = 0; i < num; i++) {
    wal[i].walk();
    wal[i].display();
  }
}



class walker {
  int x, y;
  float r, g, b;

  walker(float red, float green, float blue) {
    x = width/2;
    y = height/2; 
    r = red;
    g= green;
    b= blue;
  }

  void walk() {
    int choice = int(random(4));

    if (choice == 0) {
      x++;
    } 
    else if (choice == 1) {
      x--;
    }
    else if (choice == 2) {
      y++;
    }
    else {
      y--;
    }

    x = constrain(x, 0, width-1);
    y = constrain(y, 0, height-1);
  }



  void display() {

    stroke(r, g, b);
    point(x, y);
  }
}

然后我添加了一些填充文本，因为我被告知我已经发布了太多的代码，即使代码上方的文本充分解释了问题而不会成为光顾或偏离主题。

4

1 回答 1

0

嗯......据我所知，你想要一组“num”步行者。您在这里正确地初始化了您的数组：

wal = new walker[num];

您是说在对象wal中将有一个类型为“walker array”的“新”对象并保存“num”个对象（new walker[num]）；

将数组视为指向其他对象的对象。您需要初始化数组本身和它指向的对象。这当然意味着检查每个对象并指定该对象是什么。您可以在数组初始化后立即执行此操作，因此添加以下行：

for (int i = 0; i < num; i++) {
  wal[i] = new walker(255,167,15);
}

在这里，我们遍历数组，选择每个对象 (wal[i]) 并说应该有一个新的步行者，其值为 255 167 和 15 (new walker(255,167,15))

如果你不这样做，当程序试图访问数组中的一个对象(wal[i]) 时，它什么也找不到(null)，因此它会在你的脸上抛出一个很好的 nullPointerException！

为了好玩和盈利，你也可以试试这个：

for (int i = 0; i < num; i++) {
  wal[i] = new walker(random(255),random(255),random(255));
}
于 2013-09-03T19:33:15.797 回答