10

我对 Perl 非常陌生，并希望使用新的 Perl 6 语法特性来创建具有优先级的运算符的领域特定语言。例如以正确的方式解析“1 + 2 * 6”。

到目前为止，我发现的文档（例如this）没有包含优先声明运算符的语法规则示例。

我有这个非常简单的例子

use v6;

#use Grammar::Tracer;

grammar TestGrammar {

    token TOP {
        <digit> <infix> <digit>
    }

    token infix:sym<times> is equiv(&infix:<*>) { <sym> }

}

sub MAIN() {
    my $text = "1 times 2" ;
    say $text ;

    my $match = TestGrammar.parse($text);
    say $match;
}

这给了我

No such method 'infix' for invocant of type 'TestGrammar'

我只想构建一个抽象语法树。

4

1 回答 1

7

AFAIK 你不能在语法中设置中缀运算符和定义优先级等。这些目前仅适用于扩展 Perl 6。

这是一种可能的方法。它在加法之前解析乘法项，还允许使用单词或符号，例如timesor *。

use v6;

grammar TestGrammar {

    rule TOP      { <expr=.add> }

    rule add      { <expr=.multiply> +% [ <add-op> ] }
    rule multiply { <digit> +%  [ <mult-op> ] }

    proto token mult-op {*}
    token mult-op:sym<times>   { <sym>|'*' }
    token mult-op:sym<divided> { <sym>|'/' }

    proto token add-op {*}
    token add-op:sym<plus>     { <sym>|'+' }
    token add-op:sym<minus>    { <sym>|'-' }

}

sub MAIN() {
    for ("2+2", "2 + 2", "1 * 2", "1 + 2 * 6", "4 times 7 minus 3") {
        say $_;
        my $match = TestGrammar.parse($_);
        say $match;
    }
}

请注意，这%是分隔符运算符。表示由乘法运算符（ 、 或）分隔的<digit> +% [ <mult-op> ]数字列表。times*divided/

2014 年 9 月的替代解决方案：

S05确实提到虽然规则和标记是特殊方法，但两者都可以声明为 multi 并像常规方法一样接受参数。

这种方法利用递归和多调度来实现运算符优先级。

use v6;

grammar TestGrammar {

    rule TOP                { <expr(3)> }

    # operator multi-dispatch, loosest to tightest
    multi token op(3) {'+'|'-'|add|minus}
    multi token op(2) {'*'|'/'|times|divided}
    multi token op(1) {'**'}

    # expression multi-dispatch (recursive)
    multi rule expr(0)      { <digit> | '(' ~ ')' <expr(3)> }
    multi rule expr($pred)  { <expr($pred-1)> +% [ <op($pred)> ] }

}

sub MAIN() {
    for ("2+2", "2 + 2", "1 * 2", "1 + 2**3 * 6", "4 times (7 minus 3) * 3") {
        say $_;
        my $match = TestGrammar.parse($_);
        say $match;
    }
}
于 2013-09-02T07:33:42.923 回答