3

我正在阅读Real World Haskell中的单子变换器。在下面的示例中，堆栈位于Writer顶部State的Reader顶部IO。

{-# Language GeneralizedNewtypeDeriving #-}

import Control.Monad
import Control.Monad.State
import Control.Monad.Reader
import Control.Monad.Writer
import System.Directory
import System.FilePath

data AppConfig = AppConfig {
      cfgMaxDepth :: Int
    } deriving Show

data AppState = AppState {
      stDeepestReached :: Int
    } deriving Show

newtype MyApp a = MyA {
      runA :: WriterT [(FilePath,Int)] (StateT AppState (ReaderT AppConfig IO)) a
    } deriving (Monad, MonadIO, Functor, MonadReader AppConfig,
                MonadWriter [(FilePath,Int)], MonadState AppState)

runApp :: MyApp a -> Int -> IO ([(FilePath,Int)], AppState)
runApp k maxDepth = let config = AppConfig maxDepth
                        state' = AppState 0
                     in runReaderT (runStateT (execWriterT $ runA k) state') config

constrainedCount :: Int -> FilePath -> MyApp ()
constrainedCount curDepth path = do
  contents <- liftIO . getDirectoryContents $ path
  cfg <- ask
  let maxDepth = cfgMaxDepth cfg
  tell [(path,curDepth)]
  forM_ (filter (\d' -> d' /= ".." && d' /= ".") contents) $ \d -> do
    let newPath = path </> d
    isDir <- liftIO $ doesDirectoryExist newPath
    when (isDir && curDepth < maxDepth) $ do
         let newDepth = curDepth+1
         st <- get
         when (stDeepestReached st < newDepth) $
             put st { stDeepestReached = newDepth }
         constrainedCount newDepth newPath

main = runApp (constrainedCount 0 "/tmp") 2 >>= print

我（想我）了解我如何简单地调用ask，get并且put由于这些是在 , 和类型类中定义的MonadReader，MonadWriter并且MonadState存在诸如MonadWriter (StateT s m)等等之类的实例。

我不明白的是为什么我不能lift从下面的层到当前的 monad 转换器显式地执行一个动作。如果constrainedCount我理解正确，我在 Reader monad 中，我认为两者都st <- get应该st <- lift get工作。（那tell还有lift .lift .tell should be the same). If I changest <- get tost <- lift get`我得到了错误

Couldn't match type `t0 m0' with `MyApp'
Expected type: MyApp ()
Actual type: t0 m0 ()

这告诉我很少......我对此的理解完全错误吗？

4

1 回答 1

9

让我们看一下 的类型lift get：

lift get :: (MonadTrans t, MonadState a m) => t m a

但你MyApp不是一个单子转换器，它只是一个单子。但是里面的东西当然是，所以如果你使用

    st <- MyA $ lift get

有用。

于 2013-08-29T20:11:54.100 回答