0

我正在尝试从 Excel（VBA）创建一个 powerpoint（带模板）并为每张幻灯片添加一个文本框。

我想在其中添加文本框的代码行失败，索引超出范围/没有活动演示。这里有什么问题？幻灯片的索引应该没问题 - 如果我手动设置索引没有任何变化。

Dim PowerPointApp As Object
Set PowerPointApp = CreateObject("PowerPoint.Application")
PowerPointApp.Visible = True


Set objP = PowerPointApp.Presentations.Add
objP.ApplyTemplate "" & Table1.Range("A1").Value & "draft.pptx"

PowerPointApp.ActivePresentation.Slides.Add 1, ppLayoutTitle

For i = 1 To 10

 objP.ApplyTemplate "" & Table2.Range("A1").Value & "template.pptx"
 PowerPointApp.ActivePresentation.Slides.Add i + 1, ppLayoutBlank
 PowerPointApp.ActivePresentation.Slides(i + 1).Select

 Table3.ChartObjects(i).CopyPicture

 PowerPointApp.ActivePresentation.Slides(i + 1).Shapes.Paste
 PowerPointApp.ActivePresentation.Slides(i + 1).Shapes(1).Top = 150
 PowerPointApp.ActivePresentation.Slides(i + 1).Shapes(1).Left = 50
 PowerPointApp.ActivePresentation.Slides(i + 1).Shapes(1).Width = 400
 PowerPointApp.ActivePresentation.Slides(i + 1).Shapes(1).Height = 300

     'Exception occurs here                            
 PowerPointApp.ActivePresentation.Slides(i + 1).Shapes.AddTextbox(msoTextOrientationHorizontal, Left:=100, Top:=100, Width:=200, Height:=50).TextFrame.TextRange.Text = "Text"
Next i
4

1 回答 1

3

您的情况的问题源于您使用的绑定类型 - 后期绑定。在这种情况下，一些 VBA 常量无法识别，它们被视为变量。

首先- 如果您将 VBE 编辑器设置为require variable declaration模式，那么您会更早地认识到该问题，因为我可以在您的代码中找到的所有三个 vba 常量都将被标记为变量：

   ppLayoutTitle
   ppLayoutBlank
   msoTextOrientationHorizontal

其次- 为了避免这个问题，您需要将所有上述常量转换为数字，它们是：

   ppLayoutTitle    =1
   ppLayoutBlank    =12
   msoTextOrientationHorizontal    =1

这样：

PowerPointApp.ActivePresentation.Slides.Add 1, 1 'ppLayoutTitle
PowerPointApp.ActivePresentation.Slides.Add i + 1, 12 'ppLayoutBlank
PowerPointApp.ActivePresentation.Slides(i + 1).Shapes.AddTextbox(1, Left:=100, Top:=100, Width:=200, Height:=50).TextFrame.TextRange.Text = "Text"

第三- 为什么它适用于两个常数中的第一个？因为两者都被识别为值等于 0 的变量。在这两种情况下，0 都是幻灯片类型的可接受参数。但是 TextBox 类型不接受 0 值..

于 2013-08-29T09:33:06.027 回答