10

如何获取 AS3 TextField 中文本的实际高度？似乎 TextField.textHeight 报告了一些不依赖于 TextField 内容的固定值。

下面的示例代码产生以下内容：

text=o p g y d j
textWidth=120.8
textHeight=**96**

text=o
textWidth=15
textHeight=**96**

text=oW
textWidth=43.3
textHeight=**96**

显然，“o”和“p”等的高度应该不同。

AS3 代码：

import flash.text.TextField;

        var format : TextFormat = new TextFormat();
        format.font = "Times New Roman";
        format.size = 30;
        format.align = TextFormatAlign.CENTER;


        var textField1 : TextField = new TextField();       
        textField1.defaultTextFormat = format;      

        textField1.selectable = false;              
        textField1.sharpness = 0;   
        textField1.embedFonts = true;   
        textField1.multiline = false;

        textField1.height = 50;
        textField1.width = 200;
        textField1.x = 10;
        textField1.y = 10;

        addChild(textField1);

        textField1.text = "o p g y d j";    
        trace("text=" + textField1.text);
        trace("textWidth=" + textField1.textWidth);
        trace("textHeight=" + textField1.textHeight);       

        textField1.text = "o";      
        trace("\ntext=" + textField1.text);
        trace("textWidth=" + textField1.textWidth);
        trace("textHeight=" + textField1.textHeight);   

        textField1.text = "oW";     
        trace("\ntext=" + textField1.text);
        trace("textWidth=" + textField1.textWidth);
        trace("textHeight=" + textField1.textHeight);       

        stop();

我猜 TextField.textHeight 不是正确的变量，但我应该改用什么？

4

3 回答 3

13

Mark Fox 是对的，textHeight它不代表文本的实际高度 - TextFieldFlash 中的经典不支持获取渲染文本的实际像素高度。真正代表的是行高 - 这是它的上升（textHeight 字体在基线以上的高度）、下降（字体在基线以下的高度）和前导（行间距）的组合。正如暗示的那样，高度是恒定的，基于字体的上升和下降，而不是实际文本的. （记住这一点，请参阅Adob​​e 在此处对术语的概述- 请注意，这TextLineMetrics对您也无济于事）。

“新的”Flash 文本引擎 (flash.text.engine) 确实包含一些属性，以获取使用该技术呈现的文本的实际高度（例如TextLine.totalHeight） - 但随后我们将进入低级别文本呈现。如果您需要使用“经典” TextField，这无论如何都无法帮助您测量文本，因为 Flash 文本引擎有自己的渲染器，它不一定以与“经典”文本相同的高度和宽度渲染文本。

您可以做的是渲染TextFieldtoBitmapData然后测量文本的边界：

// Create a completely transparent BitmapData:
var bmd:BitmapData = new BitmapData(
                            textfield.width, 
                            textfield.height, 
                            true,
                            0x00ffffff);

// Note that some cases may require you to render a Sprite/MovieClip
// CONTAINING the TextField for anything to get drawn.
// For example, AntiAliasType.ADVANCED (antialias for readability) is known to 
// not be renderable in some cases - other settings may cause nothing to be
// rendered too. In that case, simply wrap add the TextField as a child of an 
// otherwise empty Sprite/MovieClip, and pass that to draw() instead:
bmd.draw(textfield);

// This gets the bounds of pixels that are not completely transparent.
// Param 1: mask  = specifies which color components to check (0xAARRGGBB)
// Param 2: color = is the color to check for.
// Param 3: findColor = whether to bound pixels OF the specified color (true),
//                      or NOT OF the specified color (false)
//
// In this case, we're interested in:
// 1: the alpha channel (0xff000000)
// 2: being 00 (0x00......)
// 3: and want the bounding box of pixels that DON'T meet that criterium (false)
var rect:Rectangle = bmd.getColorBoundsRect(0xff000000, 0x00000000, false);

// Do remember to dispose BitmapData when done with it:
bmd.dispose();

trace("text height = " + rect.height);
trace("text width = " + rect.width);

注意准确性

这可能完全无关紧要，具体取决于您将其用于什么，但值得牢记：

这种方法显然总是会返回整个像素的结果——然而，字形的实际渲染使用子像素。

换句话说，如果将“V”和“o”的宽度测量结果相加，然后将其与“Vo”的结果进行比较，它们可能不一样。您可能会得到“40 + 35 = 74”。忽略字距调整等可能会使字母靠得更近，每个字母的渲染（位置、抗锯齿等）也可能不同，具体取决于其上下文。

于 2013-08-25T22:24:53.697 回答
3

您的问题突出了 Flash 印刷 API 中的弱语义遗留问题。

该textHeight属性表示字体的相对大小（以像素为单位），它不考虑TextField.

据我所知，没有直接的编程方法可以用 Flash 测量字形。但是，您可以对文本字段进行位图并使用 getPixel 进行猜测：

var tf:TextField = …your textfield…
var wide:int = tf.width;
var tall:int = tf.height;
var bmpd:BitmapData = new BitmapData(wide, tall, true,0xFFFFFFFF);
bmpd.draw( tf );
var totalPixels:int = wide * tall;
var index:int = totalPixels + 1;
var useIndex:int;
var xPixel:int;
var yPixel:int;
while (--index > 0) {
    useIndex = index - 1;
    xPixel = useIndex % wide;
    yPixel = int(useIndex / wide);
    var pixelColor:uint = bmpd.getPixel(xPixel, yPixel);
    // write some logic to find the y extremes where the pixelColor values are not white (or whatever background color specified when you created the BitmapData)
}
于 2013-08-25T21:52:18.670 回答
-1

你可以通过“textHeight”来做到这一点；

// Create TextField
var tf:TextField = new TextField();
tf.wordWrap = true;
tf.multiline = true;
tf.selectable = false;
tf.antiAliasType = AntiAliasType.ADVANCED;
tf.autoSize = TextFieldAutoSize.LEFT; // It's should not be "=TextFieldAutoSize.NONE;"
tf.embedFonts = true;
tf.text = "Your text here";
this.addChild(tf); 

trace(tf.textHeight);

希望它会有所帮助

于 2014-06-17T15:05:04.173 回答