29

我希望在 gen_server 上使用 Erlang 的热代码交换功能，这样我就不必重新启动它。我该怎么做？当我搜索时，我只能找到一篇提到我需要使用gen_server:code_change回调的文章。

但是，我真的找不到任何关于如何使用它的文档/示例。非常感谢任何帮助或资源链接！

4

5 回答 5

45

正如我已经提到的，正常的升级方式是创建正确的 .appup 和 .relup 文件，并让 release_handler 完成需要完成的工作。但是，您可以手动执行所涉及的步骤，如此处所述。对不起，答案很长。

以下虚拟 gen_server 实现了一个计数器。旧版本（“0”）只是将整数存储为状态，而新版本（“1”）将 {tschak, Int} 存储为状态。正如我所说，这是一个虚拟的例子。

z.erl（旧）：

-module(z).
-version("0").

-export([start_link/0, boing/0]).

-behavior(gen_server).
-export([init/1, handle_call/3, handle_cast/2, handle_info/2, terminate/2, code_change/3]).

start_link() -> gen_server:start_link({local, ?MODULE}, ?MODULE, [], [{debug, [trace]}]). 

boing() -> gen_server:call(?MODULE, boom).


init([]) -> {ok, 0}.

handle_call(boom, _From, Num) -> {reply, Num, Num+1};
handle_call(_Call, _From, State) -> {noreply, State}.

handle_cast(_Cast, State) -> {noreply, State}.

handle_info(_Info, State) -> {noreply, State}.

terminate(_Reason, _State) -> ok.

code_change(_OldVsn, State, _Extra) -> {ok, State}.

z.erl（新）：

-module(z).
-version("1").

-export([start_link/0, boing/0]).

-behavior(gen_server).
-export([init/1, handle_call/3, handle_cast/2, handle_info/2, terminate/2, code_change/3]).

start_link() -> gen_server:start_link({local, ?MODULE}, ?MODULE, [], [{debug, [trace]}]).

boing() -> gen_server:call(?MODULE, boom).


init([]) -> {ok, {tschak, 0}}.

handle_call(boom, _From, {tschak, Num}) -> {reply, Num, {tschak, Num+1}};
handle_call(_Call, _From, State) -> {noreply, State}.

handle_cast(_Cast, State) -> {noreply, State}.

handle_info(_Info, State) -> {noreply, State}.

terminate(_Reason, _State) -> ok.

code_change("0", Num, _Extra) -> {ok, {tschak, Num}}.

启动 shell，并编译旧代码。请注意 gen_server 以调试跟踪启动。

1> c(z).
{ok,z}
2> z:start_link().
{ok,<0.38.0>}
3> z:boing().
*DBG* z got call boom from <0.31.0>
*DBG* z sent 0 to <0.31.0>, new state 1
0
4> z:boing().
*DBG* z got call boom from <0.31.0>
*DBG* z sent 1 to <0.31.0>, new state 2
1

按预期工作：返回 Int，新状态为 Int+1。

现在将 z.erl 替换为新的，并执行以下步骤。

5> compile:file(z).
{ok,z}
6> sys:suspend(z).
ok
7> code:purge(z).
false
8> code:load_file(z).
{module,z}
9> sys:change_code(z,z,"0",[]).
ok
10> sys:resume(z).
ok

你刚刚做了什么： 5：编译新代码。6：暂停服务器。7：清除旧代码（以防万一）。8：加载新代码。9：在进程“z”中为模块“z”从版本“0”调用代码更改，其中 [] 作为“Extra”传递给 code_change。10：恢复服务器。

现在，如果您运行更多测试，您可以看到服务器使用新的状态格式：

11> z:boing().
*DBG* z got call boom from <0.31.0>
*DBG* z sent 2 to <0.31.0>, new state {tschak,3}
2
12> z:boing().
*DBG* z got call boom from <0.31.0>
*DBG* z sent 3 to <0.31.0>, new state {tschak,4}
3
于 2009-12-03T18:31:11.810 回答
5

您不需要在gen_server行为中使用该回调。如果您在代码升级期间更改状态的内部表示，它就在那里。

您只需要加载新模块，gen_server运行的旧版本就会升级，因为它调用了新模块。只是如果有必要，您没有机会更改表示。

于 2009-12-03T15:49:32.550 回答
3

最简单的方法是替换.beam文件并l(my_server_module).在 shell 中运行。这绕过了code_change函数，因此要求状态的表示没有改变。

如前所述，正确的做法是使用 appup 和 relup 脚本创建一个新版本。然后使用release_handler安装这个新版本。

于 2009-12-03T18:20:14.960 回答
2

如果您想以正确的方式进行操作（强烈推荐），那么您需要阅读有关 OTP 主管和应用程序的使用。

您可能比在这里阅读 OTP 设计原则用户指南更糟糕：

http://www.erlang.org/doc/design_principles/users_guide.html

于 2009-12-03T15:49:58.133 回答
0

如果你在 rebar3 上，一些手动处理已经自动化了（即 appup 和 relup 生成），你可以在这里找到更多信息：http: //lrascao.github.io/automatic-release-upgrades-in-二郎/

于 2016-09-03T14:45:20.667 回答