1

我有一个两列的列表框，我已经手动添加了要使用的条目

.AddItem (potato)
.List(.ListCount - 1, 1) = bananaTbx.Text

当用户关闭用户窗体时，所有数据都会丢失，所以我想要一个保存和退出按钮，将数据保存到工作表中。但是，它不能保存到特定的单元格，因为列表的大小是动态的，并且它们将不断地添加到工作表中的主列表中。

我试图做这样的事情来提取数据：

Dim i As Integer

'loop through each row number in the list
For i = 0 To Userform1.Listbox1.ListCount - 1
    'create sequence 1,1,2,2,3,3,4,4 ... to reference the current list row
    j = Application.WorksheetFunction.RoundDown(i + 0.5, 0)
    'create sequence 0,1,0,1,0,1,0,1 ... to reference current column in list
    If Len(CStr(i / 2)) > 1 Then
        k = 0
    Else
        k = 1
        Sheets("Data").Range("A1" & ":" & "A" & i).Value = Userform1.ListBox1.List(j, k)
    End If

错误：

1004 Object defined error

我怎样才能正确或更有效地做到这一点？

4

1 回答 1

0

我创建了一个简单的用户表单来演示如何从用户表单的多列列表框中提取值/数据

首先创建一个带有一些控件的简单用户表单

用户表单

在您的项目中添加一个新Module1的并将下面的代码粘贴在其中

Sub TestUserForm()
    UserForm1.Show
    Unload UserForm1
End Sub

在 Project Explorer (VBE) 中右键单击UserForm1并点击View Code

复制并粘贴以下代码

Private Sub CommandButton1_Click()

    With ListBox1
        .AddItem TextBox1.Value
        .List(.ListCount - 1, 1) = TextBox2.Value
    End With

End Sub

Private Sub CommandButton2_Click()

    Dim ws As Worksheet
    ' create a results sheets if you do not already have one
    Set ws = Sheets("Results")

    Dim nextAvailableRow As Long
    Dim i As Long
    For i = 0 To ListBox1.ListCount - 1
        nextAvailableRow = ws.Range("A" & Rows.Count).End(xlUp).Row + 1
        ws.Range("A" & nextAvailableRow) = ListBox1.Column(0, i)
        ws.Range("B" & nextAvailableRow) = ListBox1.Column(1, i)
    Next i

    Me.Hide
End Sub

创建一个新的电子表格并命名Results

运行TestUserForm宏

将示例数据添加到列表并单击Save按钮

结果

于 2013-08-23T12:13:13.503 回答