2

我正在使用以下脚本来捕获STDIN，STDOUT并STDERR从作为参数传递的命令中捕获。

#!/usr/bin/perl

use strict;
use warnings;

use IPC::Open3;

local(*CMD_IN, *CMD_OUT, *CMD_ERR);

my $pid = open3(*CMD_IN, *CMD_OUT, *CMD_ERR, $ARGV[0]); 

close(CMD_IN);

my @stdout_output = <CMD_OUT>;
my @stderr_output = <CMD_ERR>; 

close(CMD_OUT);
close(CMD_ERR);

waitpid ($pid, 0); # reap the exit code

print "OUT:\n", @stdout_output;
print "ERR:\n", @stderr_output;

这一切都很好，除了我不确定如何监控传递的命令是否挂起。你能建议一个方法吗？

我最初从“Programming Perl”借用了这个片段。

4

2 回答 2

6

您可以使用selectorIO::Select并提供超时。如果您想同时从 stdout 和 stderr 读取，则无论如何都应该这样做（请参阅 的文档IPC::Open3）。

这是一个使用示例程序IO::Select：

#!/usr/bin/perl

use strict;
use warnings;

use IO::Select;
use IPC::Open3;
use Symbol 'gensym';

my ($cmd_in, $cmd_out, $cmd_err);
$cmd_err = gensym;
my $pid = open3($cmd_in, $cmd_out, $cmd_err, $ARGV[0]);

close($cmd_in);

my $select = IO::Select->new($cmd_out, $cmd_err);
my $stdout_output = '';
my $stderr_output = '';

while (my @ready = $select->can_read(5)) {
    foreach my $handle (@ready) {
        if (sysread($handle, my $buf, 4096)) {
            if ($handle == $cmd_out) {
                $stdout_output .= $buf;
            }
            else {
                $stderr_output .= $buf;
            }
        }
        else {
            # EOF or error
            $select->remove($handle);
        }
    }
}

if ($select->count) {
    print "Timed out\n";
    kill('TERM', $pid);
}

close($cmd_out);
close($cmd_err);

waitpid($pid, 0); # reap the exit code

print "OUT:\n", $stdout_output;
print "ERR:\n", $stderr_output;

笔记：

  • 我使用词法变量作为文件句柄。这需要使用gensymfor 的 stderr 句柄。
  • to 的参数can_read是以秒为单位的超时。
  • 我sysread用于非缓冲 IO。
  • 如果有读取超时，我会终止孩子。
于 2013-08-22T10:29:19.580 回答
1

我根据这个答案提出了以下解决方案。

然而select，在 nwellnhof 的示例中使用和避免信号看起来更干净，这就是我接受它的原因。如果有人感兴趣，我会在这里发布：

my $pid = open3(*CMD_IN, *CMD_OUT, *CMD_ERR, $cmd);

if ($pid > 0){
    eval{
        local $SIG{ALRM} = sub {kill 9, $pid;};
        alarm 6;
        waitpid($pid, 0);
        alarm 0;
    };
}
于 2013-08-22T11:21:29.437 回答